Host-specific configuration for standalone HM gets overwritten by first host's

[vbriand]

Hello,

I am trying to update my den configuration by adding a new host-bound standalone home with a shared user aspect.

However, unless I misunderstood something and messed something up, it appears to be broken as the host-specific configuration seemingly gets overwritten by the configuration of the first host (in alphabetical order).

I wrote two similar tests highlighting this issue:

{ denTest, ... }: {
  flake.tests.standalone-homes = {
    test-multiple-homes-same-user-aspect-with-per-host-config = denTest (
      {
        den,
        config,
        ...
      }:
      {
        den.default.includes = [ den.batteries.define-user ];

        den.hosts.x86_64-linux.igloo.users.tux = { };
        den.hosts.x86_64-linux.iceberg.users.tux = { };
        den.hosts.x86_64-linux.researchStation.users.tux = { };

        den.homes.x86_64-linux."tux@igloo" = { };
        den.homes.x86_64-linux."tux@iceberg" = { };
        den.homes.x86_64-linux."tux@researchStation" = { };

        den.aspects.tux = {
          provides.igloo = { host, ... }: {
            homeManager.home.sessionVariables.HOSTNAME = host.name;
          };
          provides.iceberg = { host, ... }: {
            homeManager.home.sessionVariables.HOSTNAME = host.name;
          };
          provides.researchStation = { host, ... }: {
            homeManager.home.sessionVariables.HOSTNAME = host.name;
          };
        };

        expr = {
          igloo = config.flake.homeConfigurations."tux@igloo".config.home.sessionVariables.HOSTNAME;
          iceberg = config.flake.homeConfigurations."tux@iceberg".config.home.sessionVariables.HOSTNAME;
          researchStation =
            config.flake.homeConfigurations."tux@researchStation".config.home.sessionVariables.HOSTNAME;
        };
        expected = {
          igloo = "igloo";
          iceberg = "iceberg";
          researchStation = "researchStation";
        };
      }
    );

    test-multiple-homes-same-user-aspect-with-to-hosts-config = denTest (
      {
        den,
        config,
        ...
      }:
      {
        den.default.includes = [ den.batteries.define-user ];

        den.hosts.x86_64-linux.igloo.users.tux = { };
        den.hosts.x86_64-linux.iceberg.users.tux = { };
        den.hosts.x86_64-linux.researchStation.users.tux = { };

        den.homes.x86_64-linux."tux@igloo" = { };
        den.homes.x86_64-linux."tux@iceberg" = { };
        den.homes.x86_64-linux."tux@researchStation" = { };

        den.aspects.tux = {
          provides.to-hosts = { host, ... }: {
            homeManager.home.sessionVariables.HOSTNAME = host.name;
          };
        };

        expr = {
          igloo = config.flake.homeConfigurations."tux@igloo".config.home.sessionVariables.HOSTNAME;
          iceberg = config.flake.homeConfigurations."tux@iceberg".config.home.sessionVariables.HOSTNAME;
          researchStation =
            config.flake.homeConfigurations."tux@researchStation".config.home.sessionVariables.HOSTNAME;
        };
        expected = {
          igloo = "igloo";
          iceberg = "iceberg";
          researchStation = "researchStation";
        };
      }
    );
  };
}

Result:

{
  expected = {
    iceberg = "iceberg";
    igloo = "igloo";
    researchStation = "researchStation";
  };
  expr = {
    iceberg = "iceberg";
    igloo = "iceberg";
    researchStation = "iceberg";
  };
}

Similarly, even though the behavior is slightly different, the hosts providing to the user don't work either:

{ denTest, ... }: {
  flake.tests.standalone-homes = {
    test-multiple-homes-same-user-aspect-with-user-specific-config = denTest (
      {
        den,
        config,
        ...
      }:
      {
        den.default.includes = [ den.batteries.define-user ];

        den.hosts.x86_64-linux.igloo.users.tux = { };
        den.hosts.x86_64-linux.iceberg.users.tux = { };
        den.hosts.x86_64-linux.researchStation.users.tux = { };

        den.homes.x86_64-linux."tux@igloo" = { };
        den.homes.x86_64-linux."tux@iceberg" = { };
        den.homes.x86_64-linux."tux@researchStation" = { };

        den.aspects.igloo.provides.tux = { user, ... }: {
          homeManager.home.sessionVariables.HOSTNAME = user.host.name;
        };

        den.aspects.iceberg.provides.tux = { user, ... }: {
          homeManager.home.sessionVariables.HOSTNAME = user.host.name;
        };

        den.aspects.researchStation.provides.tux = { user, ... }: {
          homeManager.home.sessionVariables.HOSTNAME = user.host.name;
        };

        expr = {
          igloo = config.flake.homeConfigurations."tux@igloo".config.home.sessionVariables.HOSTNAME;
          iceberg = config.flake.homeConfigurations."tux@iceberg".config.home.sessionVariables.HOSTNAME;
          researchStation =
            config.flake.homeConfigurations."tux@researchStation".config.home.sessionVariables.HOSTNAME;
        };
        expected = {
          igloo = "igloo";
          iceberg = "iceberg";
          researchStation = "researchStation";
        };
      }
    );
  };
}

Result:

{
  expected = {
    iceberg = "iceberg";
    igloo = "igloo";
    researchStation = "researchStation";
  };
  expr = {
    iceberg = «error: attribute 'HOSTNAME' missing»;
    igloo = «error: attribute 'HOSTNAME' missing»;
    researchStation = «error: attribute 'HOSTNAME' missing»;
  };
}

[lucasshiva]

Are host-bound homes even a thing? I've been treating hosts and homes as separate machines kinda, so for me it wouldn't make sense to group them together under a single aspect. The following worked for me:

{ denTest, ... }:
{
  flake.tests.bogus = {

    test-something = denTest (
      {
        den,
        lib,
        config,
        ...
      }:
      {
        den.default.includes = [ den.batteries.define-user ];
        den.hosts.x86_64-linux.igloo.users.tux = { };
        den.homes.x86_64-linux."tux@iceberg" = { };

        den.aspects.tux = {
          provides.igloo = { host, ... }: {
            homeManager.home.sessionVariables.HOSTNAME = host.name;
          };
          provides.iceberg = { host, ... }: {
            homeManager.home.sessionVariables.HOSTNAME = host.name;
          };
        };

        expr = {
          igloo =
            config.flake.nixosConfigurations.igloo.config.home-manager.users.tux.home.sessionVariables.HOSTNAME;
          iceberg = config.flake.homeConfigurations."tux@iceberg".config.home.sessionVariables.HOSTNAME;
        };
        expected = {
          igloo = "igloo";
          iceberg = "iceberg";
        };
      }
    );
  };
}

One host, one home, single user.

[vbriand]

Yes, they are a thing: https://den.denful.dev/guides/home-manager/#standalone-homes-bound-to-host-os and https://den.denful.dev/guides/mutual/#standalone-homemanager---host-specific-configuration

[lucasshiva]

Yes, they are a thing: https://den.denful.dev/guides/home-manager/#standalone-homes-bound-to-host-os and https://den.denful.dev/guides/mutual/#standalone-homemanager---host-specific-configuration

That's interesting. Does that mean you can use both home-manager CLI and sudo nixos-rebuild in the same NixOS host? If so, then I might start using it as well.

[vbriand]

Yes, that's a benefit of using this approach.

[vbriand]

The first two tests are now passing since #643 has been merged so I believe the issue is now fixed.
I will open a separate discussion for the host to user relationship with a standalone HM issue in order to keep things focused.