Delegates aren't getting inlined in certain cases, when using InlineIfLambda

[vzarytovskii]

SystemAction below is not getting inlined, as it used to prior .NET7p5

namespace FSharpConsole
module Foo =
    open System

    type SystemAction<'a
        when 'a: struct and 'a :> IConvertible>
            = delegate of byref<'a> -> unit

    let inline doAction (span: Span<'a>) ([<InlineIfLambda>] action: SystemAction<'a>) =
        for i = 0 to span.Length - 1 do
        	let batch = &span[i]
        	action.Invoke &batch
    [<EntryPoint>]
    let main args =
        let array = Array.zeroCreate 100
        doAction (array.AsSpan()) (SystemAction<int>(fun batch-> batch <- batch + 1))
        0

Last compiler where it worked - .NET7 p4 = 8854f5d 8854f5d1
Last compiler where it broke - .NET7p5 = a4208e9 a4208e91
Diff - https://github.com/dotnet/fsharp/compare/8854f5d1..a4208e91
Commits - 8854f5d...a4208e9
Likely suspect - 1b39cde

This issue broke performance in my ECS engine. Would love to see a fix :)

[En3Tho]

I think it has something to do with generics. I've stumled upon this once and had to introduce a function type instead of delegate.

[vzarytovskii]

I think it has something to do with generics. I've stumled upon this once and had to introduce a function type instead of delegate.

Yeah, this works fine:

namespace FSharpConsole
module Foo =
    open System

    type SystemAction = delegate of byref<int> -> unit

    let inline doAction (span: Span<int>) ([<InlineIfLambda>] action: SystemAction) =
        for i = 0 to span.Length - 1 do
            let batch = &span[i]
            action.Invoke &batch
    
    [<EntryPoint>]
    let main _ =
        let array = Array.zeroCreate 100
        doAction (array.AsSpan()) (SystemAction(fun batch-> batch <- batch + 1))
        0

Just presense of type parameter on a delegate breaks codegen.

[vzarytovskii]

Simpler example:

This won't inline:

namespace FSharpConsole
module Foo =
    open System

    type SystemAction<'T> = delegate of byref<int> -> unit

    let inline doAction (i: byref<int>) ([<InlineIfLambda>] action: SystemAction<int>) =
        action.Invoke &i

    [<EntryPoint>]
    let main _ =
        let mutable i = 1
        doAction &i (SystemAction<int>(fun i -> i <- i + 42))
        Console.WriteLine(i)
        0

This will:

namespace FSharpConsole
module Foo =
    open System

    type SystemAction = delegate of byref<int> -> unit

    let inline doAction (i: byref<int>) ([<InlineIfLambda>] action: SystemAction) =
        action.Invoke &i

    [<EntryPoint>]
    let main _ =
        let mutable i = 1
        doAction &i (SystemAction(fun i -> i <- i + 42))
        Console.WriteLine(i)
        0