Prevent exits from leaking in ExUnit.CaptureServer

lib/ex_unit/lib/ex_unit/capture_server.ex

@@ -231,29 +231,41 @@ defmodule ExUnit.CaptureServer do
   ## :logger handler callback.
 
   def log(event, _config) do
-    :ets.tab2list(@ets)
-    |> Enum.filter(fn {_ref, _string_io, level, _formatter_mod, _formatter_config} ->
-      :logger.compare_levels(event.level, level) in [:gt, :eq]
-    end)
-    |> Enum.group_by(
-      fn {_ref, _string_io, _level, formatter_mod, formatter_config} ->
-        {formatter_mod, formatter_config}
-      end,
-      fn {_ref, string_io, _level, _formatter_mod, _formatter_config} ->
-        string_io
-      end
-    )
-    |> Enum.map(fn {{formatter_mod, formatter_config}, string_ios} ->
-      Task.async(fn ->
-        chardata = formatter_mod.format(event, formatter_config)
-
-        # Simply send, do not wait for reply
-        for string_io <- string_ios do
-          send(string_io, {:io_request, self(), make_ref(), {:put_chars, :unicode, chardata}})
+    {:trap_exit, trapping_exits?} = Process.info(self(), :trap_exit)
+
+    tasks =
+      :ets.tab2list(@ets)
+      |> Enum.filter(fn {_ref, _string_io, level, _formatter_mod, _formatter_config} ->
+        :logger.compare_levels(event.level, level) in [:gt, :eq]
+      end)
+      |> Enum.group_by(
+        fn {_ref, _string_io, _level, formatter_mod, formatter_config} ->
+          {formatter_mod, formatter_config}
+        end,
+        fn {_ref, string_io, _level, _formatter_mod, _formatter_config} ->
+          string_io
         end
+      )
+      |> Enum.map(fn {{formatter_mod, formatter_config}, string_ios} ->
+        Task.async(fn ->
+          chardata = formatter_mod.format(event, formatter_config)
+
+          # Simply send, do not wait for reply
+          for string_io <- string_ios do
+            send(string_io, {:io_request, self(), make_ref(), {:put_chars, :unicode, chardata}})
+          end
+        end)
       end)
-    end)
-    |> Task.await_many(:infinity)
+
+    Task.await_many(tasks)
+
+    if trapping_exits? do
+      for %{pid: pid} <- tasks do
+        receive do
+          {:EXIT, ^pid, _} -> :ok
+        end
+      end
+    end
 
     :ok
   end

lib/ex_unit/test/ex_unit/capture_log_test.exs

@@ -95,6 +95,16 @@ defmodule ExUnit.CaptureLogTest do
     end)
   end
 
+  test "exits don't leak" do
+    Process.flag(:trap_exit, true)
+
+    capture_log(fn ->
+      Logger.error("oh no!")
+    end)
+
+    refute_receive {:EXIT, _, _}
+  end
+
   describe "with_log/2" do
     test "returns the result and the log" do
       {result, log} =