bug on codeblock/WITH OBJECT

[JoseQuintas]

Foto do perfil de jmcqu...@gmail.com
jmcqu...@gmail.com
26 de nov. de 2024, 15:28:18 (há 12 horas)
para Harbour Developers

REQUEST HB_CODEPAGE_PTISO

#include "hbclass.ch"

PROCEDURE Main()

   LOCAL a, b, c

   SetMode(25,80)
   CLS
   Set( _SET_CODEPAGE, "PTISO" )

   a := TestObj():New()
   WITH OBJECT a
      :x := 10
      c := { || :x }
   ENDWITH
   b := TestObj():New()
   WITH OBJECT b
      ? eval( c )
      ? a:x
   ENDWITH

   Inkey(0)

   RETURN

CREATE CLASS TestObj
   VAR x INIT 0
   ENDCLASS

Show
0
10

on first WITH OBJECT, I create codeblock with a:x
On second WITH OBJECT, codeblock returns b:x, not a:x

[dszlage]

This code does not indicate a bug in Harbour but rather illustrates the mechanism of how codeblocks work and their association with the current object.

The codeblock, defined in the first WITH OBJECT a, contains a reference to :x, which, at the time of evaluation, is bound to the current object context. When the codeblock c is executed within WITH OBJECT b, it references the :x field of that object (b), not the original object a.

The reason for this behavior is as follows:
• A codeblock like { || :x } is not “permanently bound” to the object in which it was defined.
• During the execution of EVAL(c), the codeblock refers to the object context in the current scope, which in this case is b.

If you want the codeblock to always refer to a:x, you would need to define it explicitly, for example:

c := { || a:x }

In summary, this behavior is consistent with the rules of Harbour and demonstrates the dynamic nature
of codeblock binding to the current context. It is not a bug but a result of the language functioning as intended.

[alcz]

That's interesting dynamism with codeblocks and WITH OBJECT. One could complain that such generalized codeblock can't be created (not called!) outside of WITH OBJECT block. Other than that i don't percieve this as as bug.

https://os.allcom.pl/hb/3.2/#!eJx1kV9PwjAUxd_7KU7wZUuIjBcflhgzRoMzuOn-4CPpSuMqoyPbFBLxu9vCQGKg6UPv-d2ec5veSMXLz4VAr8h5yZrmlhc9Ql7iyKfjLKZ4ZlJZNiEAppHvTcH6yPvgeqs-xB4wuPdIRdNG-Ydlu6HY6BtaHwx0k2Hf2O3g7v0VWwngxzBa11UN6jh3QyBYrUvJZYtGqAWqtahZq-lGtgVUhbcgfUQ0eqJ-CqnQyPeiNRHnOjOCXu7WZA6druR_E2x18lG9MpjBNBwbX3PMrzztPDfvLB9Av1hp6UD7pDB3-5-qAz6GmPOIToIQCX3NaOjTg_l8nteCLUdlxZeWsC9nxNSPZjRGlgThRP9G1yTcsWh4LdetrFQXdrI3Nbkw0MEvzeKQED-mXkrhT70kOT7f8JkXY4sgDFI4ne--h_wC2JWUxg

Some experiments with :classname too, it doesn't RTE when code block is called outside of "scope".

#include "hbclass.ch"

PROCEDURE Main()

   LOCAL a, b, c, cn, e

   a := TestObj():New()
   // cn := { || :classname  } // Error E0061  Implicit send operator with no WITH OBJECT in sight
   WITH OBJECT a
      :x := 10
      c := { || :x  }
      cn := { || :classname  }
   ENDWITH
   b := TestObj():New()
   WITH OBJECT b
      ? Eval( c )
      ? a:x
      ? Eval( cn )
   ENDWITH

   BEGIN SEQUENCE WITH __breakBlock(e)
      ? Eval( c )
   RECOVER USING e
      ? e:Description
   END SEQUENCE
   
   ? Eval( cn )
   
   RETURN

CREATE CLASS TestObj
   VAR x INIT 0
   ENDCLASS