OO accessors

[naartjie]

Hi. I'm using a class to store a user's profile information. I would like to check if the birthday which is being set on the profile is valid, inside of a setter method.

Does moonscript have get/set accessor semantics built in already or are workarounds such as this gist the way to go? Or am I completely missing the point, and should I be applying something else here?

Thanks

[naartjie]

Hi @leafo, I have cleaned up the gist from above, and have come up with this: https://gist.github.com/naartjie/9005e81811c4df6a595b.

It would be great to hear from you about your opinion, but I'm closing this for now, as it pretty much solves my original issue. Thanks for a cool language 😸

[leafo]

Hmm, doesn't look like you're referencing the old base, so you wouldn't get any class properties on the instance.

Here's a quick example I threw together:

accessors = (cls, getters={}, setters={}) ->
  cls.__base.__index = (key) =>
    if getter = getters[key]
      getter @
    else
      cls.__base[key]

  cls.__base.__newindex = (key, val) =>
    if setter = setters[key]
      setter @, val
    else
      rawset @, key, val

class Foo
  accessors @, {
    number: => math.random!
    me: => @
  }, {
    color: (val) =>
      print "Attempted to set color to", val
  }

  new: =>
    @instance_thing = 1234

  some_method: =>
    print "hi"

And a little test

f = Foo!

print f.number
print f.instance_thing
assert f.me == f

f\some_method!

f.color = 2345

This will have some trouble with inheritance if the getter/setter class is a super class, I can come up with a more full example if you want.

[naartjie]

@leafo thanks for the reply, this looks cool!!

I will try digest this and go over the superclass case and post back here.

[naartjie]

Okay, so this looks good, so long as I'm not using inheritance with getters/setters in the super class I should be fine. Thanks a lot.

[naartjie]

I have updated the gist to your solution 🎱 with a slightly modified syntax, which lets you:

  class MyClass

    getters @,
      field1: => @_field1

    setters @,
      field1: (val) => @_field1 = val