[Feature] Replicate `denote-find-backlink`

[mehimme]

Hi there, I am a denote user and this looked like an interesting project.

Just wondering if there's a simple way to replicate denote-find-backlink and denote-find-link? Essentially, instead of opening a dedicated buffer for backlinks, using minibuffer completion to jump to any file that links to the current file, and any files that it links to.

[meedstrom]

Hm. To write such a command, you'll need this expression. It returns the list of backlinks for the node at point:

(org-mem-id-links-to-entry
 (org-mem-entry-by-id
  (org-entry-get-with-inheritance "ID")))

Something like this. It's basic, but works on my end (if the node at point has backlinks at all).

(defun my-find-backlink ()
  (interactive)
  (unless (org-entry-get-with-inheritance "ID")
    (user-error "No ID at point, so no ID-backlinks possible"))
  (let* ((backlinks-for-here (org-mem-id-links-to-entry
                              (org-mem-entry-by-id
                               (org-entry-get-with-inheritance "ID"))))
         (entry-link-alist
          (cl-loop for link in backlinks-for-here
                   when (org-mem-link-nearby-id link)
                   ;; The "source entry" for each backlink
                   collect (cons (org-mem-entry-by-id (org-mem-link-nearby-id link))
                                 link)))
         (_ (when (null entry-link-alist)
              (user-error "No backlinks found")))
         (collection
          (cl-loop for (entry . link) in entry-link-alist
                   collect (cons (org-mem-entry-title entry)
                                 entry)))
         (selected-title (completing-read "Backlinked entry: " collection))
         (selected-entry (cdr (assoc selected-title collection)))
         (link-pos (org-mem-link-pos (cdr (assoc selected-entry entry-link-alist)))))
    (org-node-goto selected-entry)
    (goto-char link-pos)))