[Event Request] Codeunit 11725 "Cash Document-Release CZP".CheckMandatoryFields

[fridrichovsky]

Why do you need this change?

We need skip CashDocumentHeaderCZP.TestField(CashDocumentHeaderCZP."Payment Purpose"); because our customization use different fill for payment purpose. It is reason why we don't want check this field. Event is prepared more generally for others. Event allows set fields for skip and developers can set each field what they want. So it is not necessary create variables for each skip.

Describe the request

local procedure CheckMandatoryFields(CashDocumentHeaderCZP: Record "Cash Document Header CZP")
    var
        //---------------------------------------OnBeforeCheckMandatoryFields::BEGIN
        SkipTestFields: Dictionary of [Integer, Boolean];
        //---------------------------------------OnBeforeCheckMandatoryFields::END
    begin
        //---------------------------------------OnBeforeCheckMandatoryFields::BEGIN
        OnBeforeCheckMandatoryFields(CashDocumentHeaderCZP, SkipTestFields);
        //---------------------------------------OnBeforeCheckMandatoryFields::END

        CashDocumentHeaderCZP.TestField(CashDocumentHeaderCZP."No.");
        CashDocumentHeaderCZP.TestField(CashDocumentHeaderCZP."Posting Date");
        CashDocumentHeaderCZP.VATRounding();
        CashDocumentHeaderCZP.CalcFields(CashDocumentHeaderCZP."Amount Including VAT", CashDocumentHeaderCZP."Amount Including VAT (LCY)");
        CashDocumentHeaderCZP.TestField(CashDocumentHeaderCZP."Amount Including VAT");
        CashDocumentHeaderCZP.TestField(CashDocumentHeaderCZP."Amount Including VAT (LCY)");
        CashDocumentHeaderCZP.TestField(CashDocumentHeaderCZP."Document Date");
        //---------------------------------------OnBeforeCheckMandatoryFields::BEGIN
        if not SkipTestFields.ContainsKey(CashDocumentHeaderCZP.FieldNo("Payment Purpose")) then
        //---------------------------------------OnBeforeCheckMandatoryFields::END
            CashDocumentHeaderCZP.TestField(CashDocumentHeaderCZP."Payment Purpose");
        if CashDocumentHeaderCZP."Currency Code" <> '' then
                CashDocumentHeaderCZP.TestField(CashDocumentHeaderCZP."Currency Factor");

        GetCashDesk(CashDocumentHeaderCZP."Cash Desk No.");
        case CashDeskCZP."Payed To/By Checking" of
            CashDeskCZP."Payed To/By Checking"::Warning:
                case CashDocumentHeaderCZP."Document Type" of
                    CashDocumentHeaderCZP."Document Type"::Receipt:
                        if (CashDocumentHeaderCZP."Received By" = '') or (CashDocumentHeaderCZP."Received From" = '') then
                            if not ConfirmManagement.GetResponseOrDefault(StrSubstNo(EmptyFieldQst, CashDocumentHeaderCZP.FieldCaption(CashDocumentHeaderCZP."Received By"),
                                                                                    CashDocumentHeaderCZP.FieldCaption(CashDocumentHeaderCZP."Received From")), false) then
                                Error('');
                    CashDocumentHeaderCZP."Document Type"::Withdrawal:
                        if (CashDocumentHeaderCZP."Paid By" = '') or (CashDocumentHeaderCZP."Paid To" = '') then
                            if not ConfirmManagement.GetResponseOrDefault(StrSubstNo(EmptyFieldQst, CashDocumentHeaderCZP.FieldCaption(CashDocumentHeaderCZP."Paid By"),
                                                                                    CashDocumentHeaderCZP.FieldCaption(CashDocumentHeaderCZP."Paid To")), false) then
                                Error('');
                end;
            CashDeskCZP."Payed To/By Checking"::Blocking:
                case CashDocumentHeaderCZP."Document Type" of
                    CashDocumentHeaderCZP."Document Type"::Receipt:
                        begin
                            CashDocumentHeaderCZP.TestField(CashDocumentHeaderCZP."Received By");
                            CashDocumentHeaderCZP.TestField(CashDocumentHeaderCZP."Received From");
                        end;
                    CashDocumentHeaderCZP."Document Type"::Withdrawal:
                        begin
                            CashDocumentHeaderCZP.TestField(CashDocumentHeaderCZP."Paid By");
                            CashDocumentHeaderCZP.TestField(CashDocumentHeaderCZP."Paid To");
                        end;
                end;
        end;
    end;

    //---------------------------------------OnBeforeCheckMandatoryFields::BEGIN
    [IntegrationEvent(false, false)]
    local procedure OnBeforeCheckMandatoryFields(CashDocumentHeaderCZP: Record "Cash Document Header CZP"; var SkipTestFields: Dictionary of [Integer, Boolean])
    begin
    end;
    //---------------------------------------OnBeforeCheckMandatoryFields::END

Internal work item: AB#626304

[AleksandricMarko]

Hello @fridrichovsky
As you have need for many skips, i prefer to have one OnBeforeProcedure event with isHandled to skip whole procedure.
It would be a way clearer approach.

[fridrichovsky]

Hello @AleksandricMarko,
We need skip only one, but we prepared more variable. What do you think about this. We keep option set fields as dictionary, but we use skip only for one line.

[AleksandricMarko]

Hello @fridrichovsky

From partner perspective this will be nice approach, but for us it would make additional confusion it we add this kind structure in code. Having dictionary in case where it is used just for one field, I think does not make sense. For now, I would prefer having independent Boolean variables for every testfield or group of fields/code part. It is way clearer, but I will have in mind your proposal in case we decide having some half-automated "skip part of code" improvement.

[AleksandricMarko]

✅ Analysis complete - approved for implementation

---

Implementation:

Add a new integration event OnBeforeCheckMandatoryFields at the beginning of the CheckMandatoryFields procedure of Codeunit 11725 "Cash Document-Release CZP" to allow skipping the "Payment Purpose" TestField call.

Location in CheckMandatoryFields procedure (lines 202-211):

local procedure CheckMandatoryFields(CashDocumentHeaderCZP: Record "Cash Document Header CZP")
var
    SkipPaymentPurposeTestField: Boolean;
begin
    SkipPaymentPurposeTestField := false;
    OnBeforeCheckMandatoryFields(CashDocumentHeaderCZP, SkipPaymentPurposeTestField);  // <-- New event

    CashDocumentHeaderCZP.TestField(CashDocumentHeaderCZP."No.");
    CashDocumentHeaderCZP.TestField(CashDocumentHeaderCZP."Posting Date");
    CashDocumentHeaderCZP.VATRounding();
    CashDocumentHeaderCZP.CalcFields(CashDocumentHeaderCZP."Amount Including VAT", CashDocumentHeaderCZP."Amount Including VAT (LCY)");
    CashDocumentHeaderCZP.TestField(CashDocumentHeaderCZP."Amount Including VAT");
    CashDocumentHeaderCZP.TestField(CashDocumentHeaderCZP."Amount Including VAT (LCY)");
    CashDocumentHeaderCZP.TestField(CashDocumentHeaderCZP."Document Date");
    if not SkipPaymentPurposeTestField then
        CashDocumentHeaderCZP.TestField(CashDocumentHeaderCZP."Payment Purpose");
    if CashDocumentHeaderCZP."Currency Code" <> '' then
        CashDocumentHeaderCZP.TestField(CashDocumentHeaderCZP."Currency Factor");

Event Publisher (add at the end of the codeunit with other events):

[IntegrationEvent(false, false)]
local procedure OnBeforeCheckMandatoryFields(CashDocumentHeaderCZP: Record "Cash Document Header CZP"; var SkipPaymentPurposeTestField: Boolean)
begin
end;

---

File: CashDocumentReleaseCZP.Codeunit.al

[fridrichovsky]

Thanky you @AleksandricMarko.

[JesperSchulz]

Thanks for reporting this. We agree, and we’ll publish a fix asap, either in an update for the current version or in the next major release. Please do not reply to this, as we do not monitor closed issues. If you have follow-up questions or requests, please create a new issue where you reference this one.

Build ID: 48875.