Add progress bar support

[hustcer]

Related problem

Progress reporting is a common request for custom commands, especially for those time consuming ones.

Describe the solution you'd like

For reference:

1. https://github.com/console-rs/indicatif
2. https://github.com/a8m/pb

Describe alternatives you've considered

No response

Additional context and details

No response

[skelly37]

Great idea, imo such progressbar should be a priority for cp and rm. I always missed such thing in shells

[XC3N]

@hustcer 我同意. I used to use progress but since nu is not using coreutils, it no longer works. definitely nice to have.

[adhadse]

@hustcer I think it would be way better if we have a spinner dots on the prompt with elapsed time to it's side, instead of a progress bar.

Image from SO

[mokeyish]

For long-running tasks, progress bars are really important.

[ja-he]

Just to give a bit of inspiration for any future implementation, not only would I love this for each / par-each, but this is something that, imo, parallel gets extremely right:

recording.webm

[cab404]

Did an absolutely stupid one, but a lot better than nothing.
It would be extremely nice to be able to set up and update progress bars as objects.

  let len = 120 
  print (0..(($len - 1) / 5) | each {"_"} | str join) "\r" -n

  0..($len - 1) | par-each { |item|
    if ($item mod 5 == 0) {print -n "λ"}
    sleep 100ms
  }
  print

[zivanfi]

Two more options that can be used as of now:

1. Piping into the external pv command:

def source-command [] {1.. | each { |e| sleep 0.5sec; $e }}
def sink-command [] {ignore}
def simple-pv []: any -> any { tee { to text | pv -l | ignore } }

source-command | simple-pv | sink-command

Sample output:

22.0  0:00:11 [2.00 /s] [          <=>                      ]

(Stop with Ctrl+C)

2. Recreating (a simplified version of) pv in nushell:

def simple-pv [update_interval: duration = 1sec]: any -> any {
  tee {
    each { date now }
    | enumerate
    | generate {|row, state={}|
      let current_count = $row.index
      let current_timestamp = $row.item

      if ($state == {}) {
        # Initialize state based on the first row
        return {
          next: {
            prev_count: $current_count
            first_timestamp: $current_timestamp
            prev_timestamp: $current_timestamp
            last_update_time: $current_timestamp
          }
        }
      }
      if (($current_timestamp - $state.last_update_time) >= $update_interval) {
        let count_delta = $current_count - $state.prev_count
        let timestamp_delta_sec = ($current_timestamp - $state.prev_timestamp) / 1sec
        let elapsed = ($current_timestamp - $state.first_timestamp) // 1sec * 1sec | into string | fill -w 10

        let speed = $count_delta / $timestamp_delta_sec | into string --decimals 2
        let time_per_item = $timestamp_delta_sec / $count_delta | into string --decimals 6

        print -n $"\r($current_count)  ($elapsed)  ($speed) item/sec  ($time_per_item) sec/item"

        return {
          next: {
            prev_count: $current_count
            first_timestamp: $state.first_timestamp
            prev_timestamp: $current_timestamp
            last_update_time: $current_timestamp
          }
        }
      }
      return {
        next: {
          prev_count: $current_count
          first_timestamp: $state.first_timestamp
          prev_timestamp: $current_timestamp
          last_update_time: $state.last_update_time
        }
      }
    }
  }
}

source-command | simple-pv | sink-command

Sample output:

68  34sec       2.00 item/sec  0.500264 sec/item

(Stop with Ctrl+C)

This implementation does not show a literal progress bar or calculate progress percentage or ETA, but that could also be added.

[weirdan]

This implementation does not show a literal progress bar or calculate progress percentage or ETA, but that could also be added.

A simpler implementation would be:

def simple-pv [] {
  tee { save --append --progress /dev/null }
}