How do I logout and start omarchy from the TTY properly?

[ash-roof]

I find myself needing to logout/kill my session and login again from the tty sometimes due to GPU switching on my laptop and I was wondering:

1. What's the proper way to logout? I've been using loginctl kill-session but I'm not sure if this is correct or not?
2. How do I start omarchy properly again? I have tried going to the TTY and using hyprland, but that doesn't work correctly and causes all types of bugs and keybinds not to function.

Any help is appreciated.

[Flashengo]

A mi me funciona bastante bien uwsm stop. Lo añadí como keybinding en la configuración de hyprland ligado a SUPER + M, que es el keybinding original de hyprland para terminar la sesión. Además añadí una entrada en omarchy-menu para cerrar la sesión. Esto último lo hice editando el ejecutable de omarchy-menu ubicado en ~/.local/share/omarchy/bin/omarchy-menu. También hice una copia de seguridad de este archivo en caso de que sea remplazado en un update.

[shrralis]

I tried 2 things:

1. the upper suggestion (uwsm stop)
2. the default hyprland way of shutting hyprland down, command -v hyprshutdown >/dev/null 2>&1 && hyprshutdown || hyprctl dispatch exit

Both lead to the same - some ugly default-styled SDDM.
Wonder if there are plans to introduce a proper "Log out" thing

[perfect-weather]

On the latest version there is a /usr/share/ssdm/themes/omarchy theme which is used in SSDM /etc/sddm.conf.d/autologin.conf and looks quite nice and minimalistic.

After adding a hyprctl dispatch exit at the end of the omarchy-system-logout file and some tweaks in Main.qml I achieved the behavior I expected from the Logout button.

Main.qml

import QtQuick 2.0
import SddmComponents 2.0

Rectangle {
    id: root
    width: 640
    height: 480
    color: "#000000"

    property var sessionIndex: {
        for (var i = 0; i < sessionModel.rowCount(); i++) {
            var name = (sessionModel.data(sessionModel.index(i, 0), Qt.DisplayRole) || "").toString()
            if (name.indexOf("uwsm") !== -1)
                return i
        }
        return sessionModel.lastIndex
    }

    Connections {
        target: sddm
        function onLoginFailed() {
            errorMessage.text = "Login failed"
            password.text = ""
            password.focus = true
        }
        function onLoginSucceeded() {
            errorMessage.text = ""
        }
    }

    Column {
        anchors.centerIn: parent
        spacing: root.height * 0.04
        width: parent.width

        Image {
            source: "logo.svg"
            width: root.width * 0.35
            height: Math.round(width * sourceSize.height / sourceSize.width)
            fillMode: Image.PreserveAspectFit
            anchors.horizontalCenter: parent.horizontalCenter
        }

        Row {
            anchors.horizontalCenter: parent.horizontalCenter
            spacing: root.width * 0.007

            Text {
                text: "\uf007"
                color: "#ffffff"
                font.family: "JetBrainsMono Nerd Font"
                font.pixelSize: root.height * 0.025
                anchors.verticalCenter: parent.verticalCenter
            }

            Rectangle {
                width: root.width * 0.17
                height: root.height * 0.04
                color: "#000000"
                border.color: "#ffffff"
                border.width: 1
                clip: true

                TextInput {
                    id: name
                    text: userModel.lastUser
                    anchors.fill: parent
                    anchors.margins: root.height * 0.008
                    verticalAlignment: TextInput.AlignVCenter
                    font.family: "JetBrainsMono Nerd Font"
                    font.pixelSize: root.height * 0.02
                    font.letterSpacing: root.height * 0.004
                    color: "#ffffff"

                    KeyNavigation.tab: password; KeyNavigation.backtab: password

                    Keys.onPressed: {
                        if (event.key === Qt.Key_Return || event.key === Qt.Key_Enter) {
                            sddm.login(name.text, password.text, sessionIndex)
                            event.accepted = true
                        }
                    }
                }
            }
        }

        Row {
            anchors.horizontalCenter: parent.horizontalCenter
            spacing: root.width * 0.007

            Text {
                text: "\uf023"
                color: "#ffffff"
                font.family: "JetBrainsMono Nerd Font"
                font.pixelSize: root.height * 0.025
                anchors.verticalCenter: parent.verticalCenter
            }

            Rectangle {
                width: root.width * 0.17
                height: root.height * 0.04
                color: "#000000"
                border.color: "#ffffff"
                border.width: 1
                clip: true

                TextInput {
                    id: password
                    anchors.fill: parent
                    anchors.margins: root.height * 0.008
                    verticalAlignment: TextInput.AlignVCenter
                    echoMode: TextInput.Password
                    font.family: "JetBrainsMono Nerd Font"
                    font.pixelSize: root.height * 0.02
                    font.letterSpacing: root.height * 0.004
                    passwordCharacter: "\u2022"
                    color: "#ffffff"

                    KeyNavigation.tab: name; KeyNavigation.backtab: name

                    Keys.onPressed: {
                        if (event.key === Qt.Key_Return || event.key === Qt.Key_Enter) {
                            sddm.login(name.text, password.text, sessionIndex)
                            event.accepted = true
                        }
                    }
                }
            }
        }

        Text {
            id: errorMessage
            text: ""
            color: "#f7768e"
            font.family: "JetBrainsMono Nerd Font"
            font.pixelSize: root.height * 0.018
            anchors.horizontalCenter: parent.horizontalCenter
        }
    }

    Component.onCompleted: {
        if (name.text == "")
            name.focus = true
        else
            password.focus = true
    }
}