Signing redirect URLs fails with Crypt::OpenSSL::RSA 0.37

[MartijnVdS]

We upgraded Crypt::OpenSSL::RSA to the recently released version 0.37.

After this, we started seeing errors when generating redirect-urls for logging in:

RSA.xs:983: OpenSSL error: illegal or unsupported padding mode at /usr/local/lib/perl5/site_perl/5.42.0/Net/SAML2/Binding/Redirect.pm line 211.

Rolling back to Crypt::OpenSSL::RSA 0.35 fixes the issue.

[MartijnVdS]

We just noticed that signing metadata also fails with the newer RSA library version.

[timlegge]

Hi,

I will take a look but it will be in about 8 or 10 hours.

Tim

[timlegge]

@MartijnVdS @waterkip I have reviewed the issue and it looks like the simplest fix is to move from Crypt::OpenSSL::RSA to Crypt::PK::RSA. I probably should have done that a while ago because XML::Enc uses Crypt::PK::RSA and it should reduce the dependencies a little.

I have a working version in my local git repo for Net::SAML2 and XML::Sig. However, the changes are significant enough (library is changing) that I will need to test against some real IdPs (the actual diff is fairly small if .

That will take till the end of the week at the earliest.

If you want to test the changes for the redirect be aware that other than validating that the test suite passed I have not done anything else. Do not use in production - wait till I release a tested version. Signing the metadata is related to XML::Sig and that's a little bigger:

diff --git a/lib/Net/SAML2/Binding/Redirect.pm b/lib/Net/SAML2/Binding/Redirect.pm
index d385198..6dbf8cd 100644
--- a/lib/Net/SAML2/Binding/Redirect.pm
+++ b/lib/Net/SAML2/Binding/Redirect.pm
@@ -4,7 +4,7 @@ use Moose;
 # VERSION
 
 use Carp qw(croak);
-use Crypt::OpenSSL::RSA;
+use Crypt::PK::RSA;
 use Crypt::OpenSSL::X509;
 use File::Slurper qw/ read_text /;
 use IO::Compress::RawDeflate qw/ rawdeflate /;
@@ -197,10 +197,8 @@ sub _sign_redirect_uri {
     my $uri  = shift;
 
     my $key_string = read_text($self->key);
-    my $rsa_priv = Crypt::OpenSSL::RSA->new_private_key($key_string);
-
-    my $method = "use_" . $self->sig_hash . "_hash";
-    $rsa_priv->$method;
+    my $pk = Crypt::PK::RSA->new();
+    my $rsa_priv = $pk->import_key(\$key_string);
 
     $uri->query_param('SigAlg',
         $self->sig_hash eq 'sha1'
@@ -208,7 +206,7 @@ sub _sign_redirect_uri {
         : 'http://www.w3.org/2001/04/xmldsig-more#rsa-' . $self->sig_hash);
 
     my $to_sign = $uri->query;
-    my $sig = encode_base64($rsa_priv->sign($to_sign), '');
+    my $sig = encode_base64($rsa_priv->sign_message($to_sign, uc($self->sig_hash), 'v1.5'), '');
     $uri->query_param('Signature', $sig);
     return $uri->as_string;
 }
@@ -289,24 +287,26 @@ sub _verify {
 
     foreach my $crt (@{$self->cert}) {
         my $cert = Crypt::OpenSSL::X509->new_from_string($crt);
-        my $rsa_pub = Crypt::OpenSSL::RSA->new_public_key($cert->pubkey);
+        my $pk = Crypt::PK::RSA->new();
+        my $rsa_pub = $pk->import_key(\$cert->pubkey);
 
+        my $hash_name;
         if ($sigalg eq 'http://www.w3.org/2001/04/xmldsig-more#rsa-sha256') {
-            $rsa_pub->use_sha256_hash;
+            $hash_name = 'SHA256';
         } elsif ($sigalg eq 'http://www.w3.org/2001/04/xmldsig-more#rsa-sha224') {
-            $rsa_pub->use_sha224_hash;
+            $hash_name = 'SHA224';
         } elsif ($sigalg eq 'http://www.w3.org/2001/04/xmldsig-more#rsa-sha384') {
-            $rsa_pub->use_sha384_hash;
+            $hash_name = 'SHA384';
         } elsif ($sigalg eq 'http://www.w3.org/2001/04/xmldsig-more#rsa-sha512') {
-            $rsa_pub->use_sha512_hash;
+            $hash_name = 'SHA512';
         } elsif ($sigalg eq 'http://www.w3.org/2000/09/xmldsig#rsa-sha1') {
-            $rsa_pub->use_sha1_hash;
+            $hash_name = 'SHA1';
         }
         else {
             warn "Unsupported Signature Algorithim: $sigalg, defaulting to sha256" if $self->debug;
         }
 
-        return 1 if $rsa_pub->verify($signed, $sig);
+        return 1 if $rsa_pub->verify_message($sig, $signed, $hash_name, 'v1.5');
 
         warn "Unable to verify with " . $cert->subject if $self->debug;
     }

[timlegge]

Releasing to cpan shortly