Could not reproduce 3Dchart in Chart.Grid

[usmanzafar289]

Trying to reproduce https://plotly.com/python/3d-subplots/ in F#
Chart.Grid working for 2D charts but when I tried to add 3D chart in Chart.Grid it is not working. In documentation of plotly.net, I found LayoutGrid but no example found how to use it. Also tried Chart.withLayoutGrid but didn't work.

[kMutagene]

You have to set the domain of the scene used in the 3D plots and assign them to the grid via the column and row parameters. this is done automatically for 2D charts in Chart.grid, but has not be extended to the other trace types. Here is an example on how to set it per hand and mix it with 2D charts as well (note that Chart.Point3d will be available in preview.7):

let scene1 = Scene.init(Domain = Domain.init(Row = 0, Column = 1))

let scene2 = Scene.init(Domain = Domain.init(Row = 0, Column = 3))

let p1 = 
    Chart.Point3d(
        [1,2,3; 4,5,6; 7,8,9],
        Labels = ["A"; "B"; "C"],
        TextPosition = StyleParam.TextPosition.BottomCenter 
    )
    |> GenericChart.mapTrace(
        Trace3d.Trace3dStyle.Scatter3d(
            Scene = StyleParam.SubPlotId.Scene 1
        )
    )

let p2 = 
    Chart.Point3d(
        [1,2,3; 4,5,6; 7,8,9],
        Labels = ["A2"; "B2"; "C2"],
        TextPosition = StyleParam.TextPosition.BottomCenter 
    )
    |> GenericChart.mapTrace(
        Trace3d.Trace3dStyle.Scatter3d(
            Scene = StyleParam.SubPlotId.Scene 2
        )
)

let c1 = Chart.Line([1,2; 3,4])
let c2 = Chart.Line([1,2; 3,4])

[c1;p1;c2;p2]
|> Chart.Grid(1,4,Pattern=StyleParam.LayoutGridPattern.Coupled)
|> Chart.withScene(scene1, StyleParam.SubPlotId.Scene 1)
|> Chart.withScene(scene2, StyleParam.SubPlotId.Scene 2)
|> Chart.withSize(1000.,500.)
|> Chart.show