Chart.Pie missing parameters and abstractions

[gaviei]

#r "nuget: Plotly.NET, 2.0.0-preview.6"
#r "nuget: Plotly.NET.Interactive, 2.0.0-preview.6"
open Plotly.NET

let colors = ["gold"; "mediumturquoise"; "darkorange"; "lightgreen"]
let labels = ["Oxygen"; "Hydrogen"; "Carbon_Dioxide"; "Nitrogen"]
let values = [4500; 2500; 1053; 500]

let layout = 
    let obj = Layout.init(Font = Font.init(Size = 12.0))
    obj?hoverinfo <- "label+percent"
    obj?textinfo <- "value"
    obj

Chart.Pie(Labels=labels, values=values, Colors = colors)
|> Chart.withLayout(layout)

[kMutagene]

I think hoverinfo must be set on traces, not the layout (see here for reference of the pie trace)

[kMutagene]

I renamed this issue, please collect all pie trace parameters you are missing here, but also take a look at TraceStyle.Pie if it has what you are looking for.

[gaviei]

Missing parameters:

I identified the following missing parameters for Pie (and possibly Doughnut):

• insideTextOrientation
• pull
• domain (not sure if should be handled by Chart.withLayoutGridStyle)
• scalegroup

insideTextOrientation

https://plotly.com/javascript/reference/pie/#pie-insidetextorientation
https://plotly.com/python/pie-charts/#controlling-text-orientation-inside-pie-sectors

#r "nuget: Plotly.NET, 2.0.0-preview.7"
#r "nuget: Plotly.NET.Interactive, 2.0.0-preview.7"
open Plotly.NET

let colors = ["gold"; "mediumturquoise"; "darkorange"; "lightgreen"]
let labels = ["Oxygen"; "Hydrogen"; "Carbon_Dioxide"; "Nitrogen"]
let values = [4500; 2500; 1053; 500]

Chart.Pie(Labels=labels, values=values, Textinfo="label+percent") 
    |> GenericChart.mapTrace(fun x -> x.SetValue("insidetextorientation", "radial")
                                      x)

pull

https://plotly.com/javascript/reference/pie/#pie-pull
https://plotly.com/python/pie-charts/#pulling-sectors-out-from-the-center

#r "nuget: Plotly.NET, 2.0.0-preview.7"
#r "nuget: Plotly.NET.Interactive, 2.0.0-preview.7"
open Plotly.NET

let labels = ["Oxygen"; "Hydrogen"; "Carbon_Dioxide"; "Nitrogen"]
let values = [4500.; 2500.; 1053.; 500.]

Chart.Pie(values,
          Labels = labels,
          Textinfo = "percent"
          ) |> GenericChart.mapTrace(fun x -> x.SetValue("pull", [0.; 0.; 0.2; 0.])
                                              x)

domain (not sure if should be handled by Chart.withLayoutGridStyle)

https://plotly.com/javascript/reference/pie/#pie-domain
https://plotly.com/python/pie-charts/#pie-charts-in-subplots

#r "nuget: Plotly.NET, 2.0.0-preview.7"
#r "nuget: Plotly.NET.Interactive, 2.0.0-preview.7"
open Plotly.NET

let labels = ["US"; "China"; "European Union"; "Russian Federation"; "Brazil"; "India"; "Rest of the World"]

let annotationFont = Font.init(Size = 20.0)

let layout = Layout.init(Title = Title.init(Text = "Global Emissions 1990-2011"),
                         Annotations = [ Annotation.init(X = 0.18, Y = 0.5, Font = annotationFont, Text = "CHG", ShowArrow = false)
                                         Annotation.init(X = 0.82, Y = 0.5, Font = annotationFont, Text = "CO2", ShowArrow = false)],
                         Width = 1200.0)

let chg = Chart.Doughnut([16; 15; 12; 6; 5; 4; 42],
                          Labels = labels,
                          Hole = 0.4,
                          Hoverinfo = "label+percent+name",
                          Name = "CHG Emissions",
                          Textinfo = "percent"
                         ) |> GenericChart.mapTrace(fun x -> x.SetValue("domain", {|x = [0.; 0.5]|})
                                                             x)

let co2 = Chart.Doughnut([27; 11; 25; 8; 1; 3; 25],
                          Labels = labels,
                          Hole = 0.4,
                          Hoverinfo = "label+percent+name",
                          Name = "CO2 Emissions",
                          Textinfo = "percent"
                         ) |> GenericChart.mapTrace(fun x -> x.SetValue("domain", {|x = [0.5; 1.0]|})
                                                             x)

[chg; co2]
|> Chart.Grid(1, 2) 
|> Chart.withLayout(layout)

scalegroup

https://plotly.com/javascript/reference/pie/#pie-scalegroup
https://plotly.com/python/pie-charts/#plot-chart-with-area-proportional-to-total-count

#r "nuget: Plotly.NET, 2.0.0-preview.7"
#r "nuget: Plotly.NET.Interactive, 2.0.0-preview.7"
open Plotly.NET

let labels = ["Asia"; "Europe"; "Africa"; "Americas"; "Oceania"]
let layout = Layout.init(Title = Title.init(Text = "World GDP"), Width = 1000.)
let scaleGroup = "one"
    
let gdp1980 = Chart.Pie([4.;7.;1.;7.;0.5],
                         Labels = labels,
                         Textinfo = "percent",
                         Name = "World GDP 1980"
                        ) |> GenericChart.mapTrace(fun x -> x.SetValue("domain", {|x = [0.0; 0.0]; y = [0.0; 1.]|})
                                                            x.SetValue("scalegroup", scaleGroup)
                                                            x.SetValue("title", "1980")
                                                            x)

let gdp2007 = Chart.Pie([21.;15.;3.;19.;1.],
                         Labels = labels,
                         Textinfo = "percent",
                         Name = "World GDP 2007"
                        ) |> GenericChart.mapTrace(fun x -> x.SetValue("domain", {|x = [0.5; 1.0]; y = [0.0; 1.]|})
                                                            x.SetValue("scalegroup", scaleGroup)
                                                            x.SetValue("title", "2007")
                                                            x)

[ gdp1980; gdp2007]
|> Chart.combine
|> Chart.withLayout(layout)
|> Chart.withLayoutGrid(LayoutGrid.init(Rows = 1, Columns = 2))

[pirrmann]

If I may, there is one more abstraction that I couldn't find on the pie chart as well.

direction

https://plotly.com/javascript/reference/pie/#pie-direction

#r "nuget: Plotly.NET, 2.0.0-preview.7"
#r "nuget: Plotly.NET.Interactive, 2.0.0-preview.7"
open Plotly.NET

let colors = ["gold"; "mediumturquoise"; "darkorange"; "lightgreen"]
let labels = ["Oxygen"; "Hydrogen"; "Carbon_Dioxide"; "Nitrogen"]
let values = [4500; 2500; 1053; 500]

Chart.Pie(Labels=labels, values=values, Textinfo="label+percent") 
    |> GenericChart.mapTrace(fun x -> x.SetValue("direction", "clockwise")
                                      x)

[kMutagene]

Multiple of these were available in the respective TraceDomainStyle function, but I added more to the top level constructors and completed the missing mones for the TraceDomainStyle.

Here is a full example setting all of the requested parameters, and more (will be available with the next release):

Chart.Doughnut(
    values = [10; 15; 15; 30; 22],
    Labels = ["some"; "random"; "slice"; "labels"; "bruh"],
    TextLabels = ["text"; "labels"; "are"; "different"; "thing"],
    TextPosition = StyleParam.TextPosition.Inside,
    Direction = StyleParam.Direction.CounterClockwise,
    Pull = 0.1,
    SectionColors = [
        Color.fromKeyword ColorKeyword.DarkCyan
        Color.fromKeyword ColorKeyword.DarkOrchid
        Color.fromKeyword ColorKeyword.DarkKhaki
        Color.fromKeyword ColorKeyword.DarkGoldenRod
        Color.fromKeyword ColorKeyword.Darkolivegreen
    ],
    Sort = false
)
|> GenericChart.mapTrace (
    TraceDomainStyle.Pie(ScaleGroup="one", InsideTextOrientation = StyleParam.InsideTextOrientation.Radial)
)
|> Chart.show

[kMutagene]

Your exact script example does not display any hover information - that seems to be working as intended. What do you mean by not working?

[MaheshPunna]

Your exact script example does not display any hover information - that seems to be working as intended. What do you mean by not working?

@kMutagene I am sorry. It was a mistake

[MaheshPunna]

@kMutagene How can I define individual section pull values?

work around:

Chart.Doughnut(Labels=labels, values=values)
|> GenericChart.mapTrace(fun t -> t?pull <- [0.;0.;0.2;0.];t)