Stringify performance

[hafedh-trimeche]

Hello,

Would TStringStream be used to enhance writing performance instead of concatenating Json elements?

function TJsonArray.Stringify: String;
var
  I: Integer;
  Item: TJsonValue;
begin
  Result := '[';
  for I := 0 to FList.Count - 1 do
  begin
    Item := TJsonValue(FList[I]);
    if I > 0 then Result := Result + ',';
    Result := Result + Item.Stringify;
  end;
  Result := Result + ']';
end;

function TJsonObject.Stringify: String;
var
  I: Integer;
  Item: TJsonPair;
begin
  Result := '{';
  for I := 0 to FList.Count - 1 do
  begin
    Item := TJsonPair(FList[I]);
    if I > 0 then Result := Result + ',';
    Result := Result + Item.Stringify;
  end;
  Result := Result + '}';
end;

Best regards.

[hafedh-trimeche]

Hello,

An idea for using TStringStream:

procedure TJsonValueHelper.InternalStringify(Stream:TStringStream;AName:string;AValue:TJsonValue);
const
  StrBoolean : array[Boolean] of string = ('false', 'true');
procedure ObjectStringify(JsonObject:Jsons.TJsonObject);
var
  i    : Integer;
  Item : TJsonPair;
begin
  Stream.WriteString('{');
  for i:=0 to JsonObject.Count-1 do
  begin
    Item := JsonObject.Items[i];
    if i>0 then Stream.WriteString(',');
    InternalStringify(Stream,Item.Name,Item.Value);
  end;
  Stream.WriteString('}');
end;
procedure ArrayStringify(JsonArray:Jsons.TJsonArray);
var
  i    : Integer;
  Item : TJsonValue;
begin
  Stream.WriteString('[');
  for i:=0 to JsonArray.Count-1 do
  begin
    Item := JsonArray.Items[i];
    if i>0 then Stream.WriteString(',');
    InternalStringify(Stream,'',Item);
  end;
  Stream.WriteString(']');
end;
begin
  if AName<>'' then Stream.WriteString('"'+AValue.Encode(AName)+'":');
  case AValue.ValueType of
    jvNone    ,
    jvNull    : Stream.WriteString('null');
    jvString  : Stream.WriteString('"'+AValue.Encode(AValue.AsString)+'"');
    jvNumber  : Stream.WriteString(FixedFloatToStr(AValue.AsNumber));
    jvBoolean : Stream.WriteString(StrBoolean[AValue.AsBoolean]);
    jvObject  : ObjectStringify(AValue.AsObject);
    jvArray   : ArrayStringify(AValue.AsArray);
  end;
end;

function TJsonValueHelper.Stringify:string;
var
  Stream : TStringStream;
begin
  Stream := TStringStream.Create;
  InternalStringify(Stream,'',Self);
  Result := Stream.DataString;
  Stream.Free;
end;

Best regards.

[rilyu]

Thank you for your suggestion.
This change needs to be tested before committing. I wrote this Json library 7 years ago, and I don’t have Delphi on my computer now.
Can you submit a pull request after passing the test?