Show example of how to send an address in a request

[boxhock]

The API reference here: https://docs.chain.link/docs/chainlink-framework/
Should be updated with an example of passing in an address in the request.

It's currently not clear how to do this. Passing an address as a uint will not work: smartcontractkit/chainlink#4064

Talked to Steve about this, and the recommended way should be something along the lines of:

req.addBytes('someAddress', abi.encodePacked(address(this)));

We should show this in the docs and make it the recommended way to do this. The only caveat here is that the value received on the CL node/external adapter will be a full word with leading zeroes, encoded with base64.

[thisguy002]

@boxhock can you clarify which example or function you're talking about specifically?

[boxhock]

@DmitryDao this would be the documentation for Chainlink.Request, and the example should probably be added around the addBytes() documentation.

[thisguy002]

@boxhock please check the PR above. It's probably wrong as I still don't fully understand how what you mentioned applies to the function description.

[aelmanaa]

hello @boxhock

actually, just tested with abi.ecncodePacked but it didn't work during the decode step in the node operator:
length insufficient 20 require 32
so I tested with the following (both work perfectly fine):

• Parsing from address to string using Openzeppelin Strings utils. : req.add('address1',Strings.toHexString(uint256(uint160(msg.sender)), 20));
• abi.encode : req.addBytes('address2',abi.encode(msg.sender));

Let me know which option you prefer

• Contract example:

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.7;

import '@chainlink/contracts/src/v0.8/ChainlinkClient.sol';
import '@openzeppelin/contracts/utils/Strings.sol';


contract APIAddressKovan is ChainlinkClient {
    using Chainlink for Chainlink.Request;

    address public response1;
    address public response2;
    bytes32 public jobId;
    uint256 public fee;

    constructor() {
        setChainlinkToken(0xa36085F69e2889c224210F603D836748e7dC0088);
        setChainlinkOracle(0x74EcC8Bdeb76F2C6760eD2dc8A46ca5e581fA656);
        jobId = '2cabb47835a34a0e8a760a61cad85aba';
        fee = (1 * LINK_DIVISIBILITY)/10; // (Varies by network and job)
    }

    
    function requestAddress() public returns (bytes32 requestId) {
        Chainlink.Request memory req = buildChainlinkRequest(jobId, address(this), this.fulfill.selector);

        // Set the URL to perform the GET request on
         
        req.add('address1',Strings.toHexString(uint256(uint160(msg.sender)), 20));
        req.addBytes('address2',abi.encode(msg.sender));
        // Sends the request
        return sendChainlinkRequest(req, fee);
    }

    
    function fulfill(bytes32 _requestId, address _address1, address _address2) public recordChainlinkFulfillment(_requestId) {
        response1 = _address1;
        response2 = _address2;
    }

    // function withdrawLink() external {} - Implement a withdraw function to avoid locking your LINK in the contract
}

• TOML job node operator:

type = "directrequest"
schemaVersion = 1
name = "Address debug - (TOML)"
externalJobID = "2cabb478-35a3-4a0e-8a76-0a61cad85aba"
maxTaskDuration = "0s"
contractAddress = "0x74EcC8Bdeb76F2C6760eD2dc8A46ca5e581fA656"
minIncomingConfirmations = 0
observationSource = """
    decode_log   [type="ethabidecodelog"
                  abi="OracleRequest(bytes32 indexed specId, address requester, bytes32 requestId, uint256 payment, address callbackAddr, bytes4 callbackFunctionId, uint256 cancelExpiration, uint256 dataVersion, bytes data)"
                  data="$(jobRun.logData)"
                  topics="$(jobRun.logTopics)"]

    decode_cbor  [type="cborparse" data="$(decode_log.data)"]
   decode [type="ethabidecode"
        abi="address address2"
        data="$(decode_cbor.address2)"]
    encode_data  [type="ethabiencode" abi="(bytes32 requestId, address _address1, address _address2)" data="{ \\"requestId\\": $(decode_log.requestId), \\"_address1\\": $(decode_cbor.address1), \\"_address2\\": $(decode.address2) }"]
    encode_tx    [type="ethabiencode"
                  abi="fulfillOracleRequest2(bytes32 requestId, uint256 payment, address callbackAddress, bytes4 callbackFunctionId, uint256 expiration, bytes calldata data)"
                  data="{\\"requestId\\": $(decode_log.requestId), \\"payment\\":   $(decode_log.payment), \\"callbackAddress\\": $(decode_log.callbackAddr), \\"callbackFunctionId\\": $(decode_log.callbackFunctionId), \\"expiration\\": $(decode_log.cancelExpiration), \\"data\\": $(encode_data)}"
                  ]
    submit_tx    [type="ethtx" to="0x74EcC8Bdeb76F2C6760eD2dc8A46ca5e581fA656" data="$(encode_tx)"]

    decode_log -> decode_cbor  -> decode -> encode_data -> encode_tx -> submit_tx
"""