Adding support for callbacks. Added the callback for PVT plus an example.

Author: PaulZC

examples/Callbacks/CallbackExample1_PVT/CallbackExample1_PVT.ino

@@ -0,0 +1,89 @@
+/*
+  Configuring the GPS to automatically send position reports over I2C and display them using a callback
+  By: Paul Clark
+  SparkFun Electronics
+  Date: December 30th, 2020
+  License: MIT. See license file for more information but you can
+  basically do whatever you want with this code.
+
+  This example shows how to configure the u-blox GPS to send navigation reports automatically
+  and access the data via a callback.
+
+  Feel like supporting open source hardware?
+  Buy a board from SparkFun!
+  ZED-F9P RTK2: https://www.sparkfun.com/products/15136
+  NEO-M8P RTK: https://www.sparkfun.com/products/15005
+  SAM-M8Q: https://www.sparkfun.com/products/15106
+
+  Hardware Connections:
+  Plug a Qwiic cable into the GPS and a BlackBoard
+  If you don't have a platform with a Qwiic connection use the SparkFun Qwiic Breadboard Jumper (https://www.sparkfun.com/products/14425)
+  Open the serial monitor at 115200 baud to see the output
+*/
+
+#include <Wire.h> //Needed for I2C to GPS
+
+#include <SparkFun_Ublox_Arduino_Library.h> //http://librarymanager/All#SparkFun_u-blox_GPS
+SFE_UBLOX_GPS myGPS;
+
+void printPVTdata() // Define the callback for NAV PVT
+{
+    Serial.println();
+
+    Serial.print(F("Time: "));
+    uint8_t hms = myGPS.packetUBXNAVPVTcopy->hour;
+    if (hms < 10) Serial.print(F("0")); Serial.print(hms); Serial.print(F(":"));
+    hms = myGPS.packetUBXNAVPVTcopy->min;
+    if (hms < 10) Serial.print(F("0")); Serial.print(hms); Serial.print(F(":"));
+    hms = myGPS.packetUBXNAVPVTcopy->sec;
+    if (hms < 10) Serial.print(F("0")); Serial.print(hms); Serial.print(F("."));
+    unsigned long millisecs = myGPS.packetUBXNAVPVTcopy->iTOW % 1000;
+    Serial.print(millisecs);
+    
+    long latitude = myGPS.packetUBXNAVPVTcopy->lat;
+    Serial.print(F(" Lat: "));
+    Serial.print(latitude);
+
+    long longitude = myGPS.packetUBXNAVPVTcopy->lon;
+    Serial.print(F(" Long: "));
+    Serial.print(longitude);
+    Serial.print(F(" (degrees * 10^-7)"));
+    
+    long altitude = myGPS.packetUBXNAVPVTcopy->hMSL;
+    Serial.print(F(" Height above MSL: "));
+    Serial.print(altitude);
+    Serial.println(F(" (mm)"));  
+}
+
+void setup()
+{
+  Serial.begin(115200);
+  while (!Serial); //Wait for user to open terminal
+  Serial.println("SparkFun Ublox Example");
+
+  Wire.begin();
+
+  //myGPS.enableDebugging(); // Uncomment this line to enable helpful debug messages on Serial
+
+  if (myGPS.begin() == false) //Connect to the Ublox module using Wire port
+  {
+    Serial.println(F("Ublox GPS not detected at default I2C address. Please check wiring. Freezing."));
+    while (1);
+  }
+
+  myGPS.setI2COutput(COM_TYPE_UBX); //Set the I2C port to output UBX only (turn off NMEA noise)
+  myGPS.saveConfigSelective(VAL_CFG_SUBSEC_IOPORT); //Save (only) the communications port settings to flash and BBR
+  
+  myGPS.setNavigationFrequency(2); //Produce two solutions per second
+  
+  myGPS.setAutoPVT(printPVTdata); // Enable automatic PVT messages with callback
+}
+
+void loop()
+{
+  myGPS.checkUblox(); // Check for the arrival of new data and process it.
+  myGPS.checkCallbacks(); // Check if any callbacks are waiting to be processed.
+  
+  Serial.print(".");
+  delay(50);
+}