setting filetype of file in popup window might reset 'cpo'

[lacygoill]

Describe the bug

Setting the filetype of a file in a popup window might reset 'cpo'.

To Reproduce

Run this shell command:

vim -Nu NONE -S <(cat <<'EOF'
    set cpo=aABceFsMny>
    filetype indent on
    let id = popup_create('', {})
    echom 'before: ' .. &cpo
    call popup_create('', {'filter': {-> win_execute(g:id, 'setf yaml')}})
    call feedkeys(":echom 'after: ' .. &cpo\r", 't')
    redraw
    mess
EOF
)

It prints:

before: aABceFsMny>
after: aABceFs

Expected behavior

It prints:

before: aABceFsMny>
after: aABceFsMny>

Environment

• Vim version: 8.2 Included patches: 1-2374
• OS: Ubuntu 16.04.7 LTS
• Terminal: xterm(363)

[lacygoill]

Actually, I can reproduce simply by executing :setf yaml twice.

[lacygoill]

Ah, I found the issue; the guard in the default indent plugin for the yaml filetype is positioned too late. It prevents 'cpo' from being restored. This patch should fix the issue:

diff --git a/runtime/indent/yaml.vim b/runtime/indent/yaml.vim
index 26e14effb..c28f94011 100644
--- a/runtime/indent/yaml.vim
+++ b/runtime/indent/yaml.vim
@@ -9,9 +9,6 @@ if exists('b:did_indent')
   finish
 endif
 
-let s:save_cpo = &cpo
-set cpo&vim
-
 let b:did_indent = 1
 
 setlocal indentexpr=GetYAMLIndent(v:lnum)
@@ -24,6 +21,8 @@ let b:undo_indent = 'setlocal indentexpr< indentkeys< smartindent<'
 if exists('*GetYAMLIndent')
     finish
 endif
+let s:save_cpo = &cpo
+set cpo&vim
 
 function s:FindPrevLessIndentedLine(lnum, ...)
     let prevlnum = prevnonblank(a:lnum-1)

[lacygoill]

the guard in the default indent plugin for the yaml filetype

This one:

vim/runtime/indent/yaml.vim

Lines 24 to 26 in 98a29d0

	if exists('*GetYAMLIndent')
	finish
	endif

It's OK the first time the indent plugin is sourced (because the function doesn't exist yet), but not the next times.

[lacygoill]

The same issue applies to the ocaml filetype plugin, and the bazel build filetype plugin. I'll try to send a patch later. Before, I'm going to test all the filetypes.

[lacygoill]

I'm going to test all the filetypes.

I've tested all the filetypes with this shell command:

vim -Nu NONE -S <(cat <<'EOF'
    vim9
    filetype plugin indent on
    set cpo=aABceFsMny>
    e /tmp/file
    def TestAllFileTypes()
        writefile([], '/tmp/buggy_filetypes.log')
        var cpo_save = &cpo
        for ft in getcompletion('*', 'filetype')
            exe 'sil! setf ' .. ft
            exe 'sil! setf ' .. ft
            if &cpo != cpo_save
                writefile([ft], '/tmp/buggy_filetypes.log', 'a')
            endif
            &cpo = cpo_save
            unlet! b:did_ftplugin b:did_indent b:current_syntax
        endfor
    enddef
    TestAllFileTypes()
EOF
)

It should write all the filetypes that have an indent or filetype plugin which reset 'cpo' inside the file /tmp/buggy_filetypes.log. On my machine, the latter contains this list:

• bzl
• fortran
• hamster
• ocaml
• raml
• yaml

Here is a patch which fixes all of them:

diff --git a/runtime/ftplugin/bzl.vim b/runtime/ftplugin/bzl.vim
index 0296b0c0b..5feed866c 100644
--- a/runtime/ftplugin/bzl.vim
+++ b/runtime/ftplugin/bzl.vim
@@ -51,6 +51,8 @@ if get(g:, 'ft_bzl_fold', 0)
 endif
 
 if exists('*BzlFoldText')
+  let &cpo = s:save_cpo
+  unlet s:save_cpo
   finish
 endif
 
diff --git a/runtime/ftplugin/hamster.vim b/runtime/ftplugin/hamster.vim
index 6c0630fe0..58da35eb8 100644
--- a/runtime/ftplugin/hamster.vim
+++ b/runtime/ftplugin/hamster.vim
@@ -59,4 +59,3 @@ endif
 setlocal ignorecase
 let &cpo = s:cpo_save
 unlet s:cpo_save
-setlocal cpo+=M		" makes \%( match \)
diff --git a/runtime/ftplugin/ocaml.vim b/runtime/ftplugin/ocaml.vim
index 793b887af..078b7d226 100644
--- a/runtime/ftplugin/ocaml.vim
+++ b/runtime/ftplugin/ocaml.vim
@@ -159,6 +159,8 @@ let b:undo_ftplugin = "setlocal efm< foldmethod< foldexpr<"
 " - Only definitions below, executed once -------------------------------------
 
 if exists("*OMLetFoldLevel")
+  let &cpoptions=s:cposet
+  unlet s:cposet
   finish
 endif
 
diff --git a/runtime/indent/fortran.vim b/runtime/indent/fortran.vim
index 696320288..90186617e 100644
--- a/runtime/indent/fortran.vim
+++ b/runtime/indent/fortran.vim
@@ -74,11 +74,15 @@ endif
 if (b:fortran_fixed_source == 1)
   setlocal indentexpr=FortranGetFixedIndent()
   if exists("*FortranGetFixedIndent")
+    let &cpoptions = s:cposet
+    unlet s:cposet
     finish
   endif
 else
   setlocal indentexpr=FortranGetFreeIndent()
   if exists("*FortranGetFreeIndent")
+    let &cpoptions = s:cposet
+    unlet s:cposet
     finish
   endif
 endif
diff --git a/runtime/indent/yaml.vim b/runtime/indent/yaml.vim
index 26e14effb..435001f2e 100644
--- a/runtime/indent/yaml.vim
+++ b/runtime/indent/yaml.vim
@@ -22,6 +22,7 @@ let b:undo_indent = 'setlocal indentexpr< indentkeys< smartindent<'
 
 " Only define the function once.
 if exists('*GetYAMLIndent')
+    let &cpo = s:save_cpo
     finish
 endif
 

---

Contrary to the previous patch, I never moved the :finish statement, because I wasn't sure it wouldn't cause other issues. Instead, I've simply added a statement to restore 'cpo' right before :finish.

Also, there was a mistake in the hamster filetype plugin:

vim/runtime/ftplugin/hamster.vim

Line 62 in 09fbedc

setlocal cpo+=M " makes \%( match \)

'cpo' is not a local option; so :setlocal doesn't work. The filetype plugin should not alter the option, so I removed the statement.

[brammool]

Thanks. Please send the changes to the respective maintainers.

I'll also improve the script I use to check the runtime files to check for this kind of errors.

[lacygoill]

OK, I'll try to contact the maintainers.