runtime(erlang): Improve application resource file detection

runtime/autoload/dist/ft.vim

@@ -29,6 +29,28 @@ export def Check_inp()
   endif
 enddef
 
+export def FTapp()
+  if exists("g:filetype_app")
+    exe "setf " .. g:filetype_app
+    return
+  endif
+  # https://erlang.org/doc/system/applications
+  const pat = '^\s*{\s*application\s*,\s*\(''\=\)' .. expand("%:t:r:r") .. '\1\s*,'
+  var line: string
+  for lnum in range(1, min([line("$"), 100]))
+    line = getline(lnum)
+    # skip Erlang comments, might be something else
+    if line =~ '^\s*%' || line =~ '^\s*$'
+      continue
+    elseif line =~ '^\s*{' &&
+	getline(lnum, lnum + 9)->filter((_, v) => v !~ '^\s*%')->join(' ') =~# pat
+      setf erlang
+      return
+    endif
+    return
+  endfor
+enddef
+
 # This function checks for the kind of assembly that is wanted by the user, or
 # can be detected from the beginning of the file.
 export def FTasm()

runtime/doc/filetype.txt

@@ -138,6 +138,8 @@ what kind of file it is.  This doesn't always work.  A number of global
 variables can be used to overrule the filetype used for certain extensions:
 
 	file name	variable ~
+	*.app		g:filetype_app
+	*.app.src	g:filetype_app_src
 	*.asa		g:filetype_asa		|ft-aspperl-syntax|
 						|ft-aspvbs-syntax|
 	*.asm		g:asmsyntax		|ft-asm-syntax|

runtime/filetype.vim

@@ -428,7 +428,7 @@ au BufNewFile,BufRead *.e,*.E			call dist#ft#FTe()
 au BufNewFile,BufRead filter-rules		setf elmfilt
 
 " Erlang
-au BufNewFile,BufRead *.app.src			setf erlang
+au BufNewFile,BufRead *.app,*.app.src		call dist#ft#FTapp()
 
 " ESMTP rc file
 au BufNewFile,BufRead *esmtprc			setf esmtprc

src/testdir/test_filetype.vim

@@ -275,7 +275,7 @@ def s:GetFilenameChecks(): dict<list<string>>
     elsa: ['file.lc'],
     elvish: ['file.elv'],
     epuppet: ['file.epp'],
-    erlang: ['file.erl', 'file.hrl', 'file.yaws', 'file.app.src', 'rebar.config'],
+    erlang: ['file.erl', 'file.hrl', 'file.yaws', 'rebar.config'],
     eruby: ['file.erb', 'file.rhtml'],
     esdl: ['file.esdl'],
     esmtprc: ['anyesmtprc', 'esmtprc', 'some-esmtprc'],
@@ -3204,4 +3204,37 @@ func Test_m4_format()
   filetype off
 endfunc
 
+func Test_app_file()
+  filetype on
+
+  for extension in ['app', 'app.src']
+
+    call writefile(['% line comment', '{application, xfile,'], $'xfile.{extension}', 'D')
+    exe $'split xfile.{extension}'
+    call assert_equal('erlang', &filetype)
+    bwipe!
+
+    call writefile(['% line comment', "{application, 'Xfile',"], $'Xfile.{extension}', 'D')
+    exe $'split Xfile.{extension}'
+    call assert_equal('erlang', &filetype)
+    bwipe!
+
+    call writefile([' % line comment',
+          \ ' ',
+          \ ' % line comment',
+          \ ' { ',
+          \ ' % line comment ',
+          \ ' application , ',
+          \ ' % line comment ',
+          \ ' xfile , '],
+          \ $'xfile.{extension}', 'D')
+    exe $'split xfile.{extension}'
+    call assert_equal('erlang', &filetype)
+    bwipe!
+
+  endfor
+
+  filetype off
+endfunc
+
 " vim: shiftwidth=2 sts=2 expandtab