support other anthropic-compatible endpoints

[lemyx]

Dear author,

Thanks for your great work, the following is my configuration for claude-code-ide, where the compatible claude-code endpoint from Kimi-k2 is used.

However, I haven't found the exposed setting options for agent-shell in the file agent-shell-anthropic.el, so will the relevant configurations be supported?

(use-package claude-code-ide
  :ensure nil
  :load-path "site-lisp/claude-code-ide"
  :commands
  (claude-code-ide-menu)
  :bind
  ("C-c C-'" . claude-code-ide-menu)
  :config

  ; https://docs.anthropic.com/en/docs/claude-code/settings#environment-variables
  ; https://platform.moonshot.cn/docs/guide/agent-support#%E8%8E%B7%E5%8F%96-api-key
  (setenv "ANTHROPIC_BASE_URL" "https://api.moonshot.cn/anthropic/")
  (setenv "ANTHROPIC_AUTH_TOKEN" (read-llm-api-key (moonshot-api-key-path)))
  (setenv "ANTHROPIC_MODEL" preferred-kimi-model)
  (setenv "ANTHROPIC_SMALL_FAST_MODEL" preferred-kimi-model)

  (setq claude-code-ide-cli-path "/usr/local/bin/claude"
        claude-code-ide-terminal-backend 'eat
	claude-code-ide-focus-on-open nil
	claude-code-ide-focus-claude-after-ediff t
	claude-code-ide-show-claude-window-in-ediff t
	)
  ;; (setq claude-code-ide-cli-debug t)
  ;; (setq claude-code-ide-debug t)
  (claude-code-ide-emacs-tools-setup)
  )

Btw, possible related thread: zed-industries/zed#37469

[xenodium]

Exposing environment variables isn't supported yet, but let's first figure out how to make this setup work and then I can look into exposing the API.

Can you eval below and try launching a claude code agent shell? (please verify I got the variables set correctly for your use case.

(defun agent-shell-anthropic-make-claude-client ()
  "Create a Claude Code ACP client using configured authentication.

Uses `agent-shell-anthropic-authentication' for authentication configuration."
  (when (and (boundp 'agent-shell-anthropic-key) agent-shell-anthropic-key)
    (user-error "Please migrate to use agent-shell-anthropic-authentication and eval (setq agent-shell-anthropic-key nil)"))
  (cond
   ((map-elt agent-shell-anthropic-authentication :api-key)
    (acp-make-client :command (car agent-shell-anthropic-claude-command)
                     :command-params (cdr agent-shell-anthropic-claude-command)
                     :environment-variables (list (format "ANTHROPIC_AUTH_TOKEN=%s"
                                                          (read-llm-api-key (moonshot-api-key-path)))
                                                  "ANTHROPIC_BASE_URL=https://api.moonshot.cn/anthropic/"
                                                  "ANTHROPIC_MODEL=moonshot-v1-auto"
                                                  "ANTHROPIC_SMALL_FAST_MODEL=moonshot-v1-auto")))
   ((map-elt agent-shell-anthropic-authentication :login)
    (acp-make-client :command (car agent-shell-anthropic-claude-command)
                     :command-params (cdr agent-shell-anthropic-claude-command)
                     :environment-variables (list "ANTHROPIC_API_KEY="
                                                  (format "ANTHROPIC_AUTH_TOKEN=%s"
                                                          (read-llm-api-key (moonshot-api-key-path)))
                                                  "ANTHROPIC_BASE_URL=https://api.moonshot.cn/anthropic/"
                                                  "ANTHROPIC_MODEL=moonshot-v1-auto"
                                                  "ANTHROPIC_SMALL_FAST_MODEL=moonshot-v1-auto")))
   (t
    (error "Invalid authentication configuration"))))

edit: I had forgotten about your token

[lemyx]

Thanks for your timely response! I modify the file ~/.emacs.d/elpa/agent-shell/agent-shell-anthropic.el as suggested.

The following is the exact code snippet.

(defun agent-shell-anthropic-make-claude-client ()
  "Create a Claude Code ACP client using configured authentication.

Uses `agent-shell-anthropic-authentication' for authentication configuration."
  (when (and (boundp 'agent-shell-anthropic-key) agent-shell-anthropic-key)
    (user-error "Please migrate to use agent-shell-anthropic-authentication and eval (setq agent-shell-anthropic-key nil)"))
  (cond
   ((map-elt agent-shell-anthropic-authentication :api-key)
    (acp-make-client :command (car agent-shell-anthropic-claude-command)
                     :command-params (cdr agent-shell-anthropic-claude-command)
                     :environment-variables (list (format "ANTHROPIC_API_KEY=%s"
                                                          (agent-shell-anthropic-key))
                                                  "ANTHROPIC_BASE_URL=https://api.moonshot.cn/anthropic"
                                                  "ANTHROPIC_MODEL=kimi-k2-turbo-preview"
                                                  "ANTHROPIC_SMALL_FAST_MODEL=kimi-k2-turbo-preview")))
   ((map-elt agent-shell-anthropic-authentication :login)
    (acp-make-client :command (car agent-shell-anthropic-claude-command)
                     :command-params (cdr agent-shell-anthropic-claude-command)
                     :environment-variables (list "ANTHROPIC_API_KEY="
                                                  "ANTHROPIC_BASE_URL=https://api.moonshot.cn/anthropic"
                                                  "ANTHROPIC_MODEL=kimi-k2-turbo-preview"
                                                  "ANTHROPIC_SMALL_FAST_MODEL=kimi-k2-turbo-preview")))
   (t
    (error "Invalid authentication configuration"))))

Here is my configuration for agent-shell

(use-package agent-shell
  :vc (:url "https://github.com/xenodium/agent-shell")
  :demand t
  :config
  (setq agent-shell-anthropic-authentication
	(agent-shell-anthropic-make-authentication :api-key (read-llm-api-key (moonshot-api-key-path))))
  )

Hope it helps.

[xenodium]

Great. With your results, I can look at exposing environment also.

Thanks for your timely response!

Consider sponsoring so I can continue providing support like this and improving the package.

[xenodium]

Ok, so I've tested with some unit tests, but I don't have the setup to test against real service. Could you try it out please? For you, it would look something like this (please adjust as needed):

   (setq agent-shell-anthropic-claude-environment
         (agent-shell-make-environment-variables
          "ANTHROPIC_BASE_URL" "https://api.moonshot.cn/anthropic"
          "ANTHROPIC_MODEL" "kimi-k2-turbo-preview"
          "ANTHROPIC_SMALL_FAST_MODEL" "kimi-k2-turbo-preview"))

Also note agent-shell-make-environment-variables can take :inherit-env t, which would bring your existing setenv values, but also enable you to override them.

[lemyx]

Thanks, the latest codes work well, the following is my configuration.

(use-package agent-shell
  :ensure nil
  :demand t
  :load-path "site-lisp/agent-shell"
  :after (acp shell-maker)
  :config
  (setq agent-shell-anthropic-authentication
        (agent-shell-anthropic-make-authentication :api-key (read-llm-api-key (moonshot-api-key-path))))
  (setq agent-shell-anthropic-claude-environment
        (agent-shell-make-environment-variables
         "ANTHROPIC_BASE_URL" "https://api.moonshot.cn/anthropic"
         "ANTHROPIC_MODEL" preferred-kimi-model
         "ANTHROPIC_SMALL_FAST_MODEL" preferred-kimi-model))
  )

[xenodium]

Great. I'll document this in the README soon (your snippet is perfect) and roll out the same environment variable approach for all the other agents.

[xenodium]

This is now documented in README. Will go ahead an close this feature request as it's now possible. Thanks for validating.