Error parsing the wast text and optimized the wast failed

[LiaoPeng]

AssemblyScript code

It's wast result

(module
 (type $v (func))
 (type $iiiiv (func (param i32 i32 i32 i32)))
 (memory $0 1 65535)
 (data (i32.const 8) "\07\00\00\00m\00a\00i\00n\00.\00t\00s")
 (table 1 anyfunc)
 (elem (i32.const 0) $null)
 (import "env" "abort" (func $~lib/env/abort (param i32 i32 i32 i32)))
 (export "memory" (memory $0))
 (export "table" (table $0))
 (export "testBreak" (func $main/testBreak))
 (start $start)
 (func $main/testBreak (; 1 ;) (; has Stack IR ;) (type $v)
  (local $0 i32)
  (local $1 i32)
  ;;@ main.ts:4:8
  (block $break|0
   (loop $repeat|0
    (br_if $break|0
     ;;@ main.ts:4:28
     (i32.ge_s
      (get_local $0)
      ;;@ main.ts:4:34
      (i32.const 32)
     )
    )
    (set_local $1
     ;;@ main.ts:5:12
     (if (result i32)
      ;;@ main.ts:5:16
      (i32.eq
       (get_local $0)
       ;;@ main.ts:5:23
       (i32.const 12)
      )
      ;;@ main.ts:6:23
      (i32.add
       (get_local $0)
       ;;@ main.ts:6:29
       (i32.const 32)
      )
      (block
       ;;@ main.ts:4:38
       (set_local $0
        (i32.add
         (get_local $0)
         (i32.const 1)
        )
       )
       (br $repeat|0)
      )
     )
    )
   )
  )
  ;;@ main.ts:10:8
  (if
   ;;@ main.ts:10:15
   (i32.ne
    (get_local $1)
    ;;@ main.ts:10:23
    (i32.const 44)
   )
   (block
    (call $~lib/env/abort
     (i32.const 0)
     (i32.const 8)
     (i32.const 10)
     (i32.const 8)
    )
    (unreachable)
   )
  )
 )
 (func $start (; 2 ;) (; has Stack IR ;) (type $v)
  ;;@ main.ts:13:4
  (call $main/testBreak)
 )
 (func $null (; 3 ;) (; has Stack IR ;) (type $v)
  (nop)
 )
)

Than I transfered the code to wasm.
I got a error. (A)

test.wat:8:3: error: imports must occur before all non-import definitions

So I changed the location of imports;Then I got the below error. (B)

test.wat:10:25: error: undefined table variable "$0"
 (export "table" (table $0))

So I removed the export table. I got the below error.(C)

test.wat:49:9: error: type mismatch in if false branch, expected [i32] but got []
       (br $repeat|0)

The error A and error B are new exceptions. I think it related the wast spec.
The error C is related the issue number 179

[dcodeIO]

Looks like Binaryen's .wat output can't be processed by what WebAssembly Studio is using to compile .wat files anymore, presumably WABT. @kripken ?

[MaxGraey]

binaryen.js and wat.js which used in WebAssembly Studio is pretty old now. Need update them

[kripken]

A fix for the import order is in WebAssembly/binaryen#1715

I'm less sure about the undefined table variable error, which is the next to appear after fixing the imports. @binji , the situation is this:

 (table 1 anyfunc)
 (export "table" (table $0))

The table is named in the export, using the implicit name which is not given before. That works for functions, I'd guess it should work for tables too, could this be a wabt bug?

[binji]

The table is named in the export, using the implicit name which is not given before. That works for functions, I'd guess it should work for tables too, could this be a wabt bug?

Not sure what you mean by implicit name here, if no name is provided then the table must be referenced by index. This works:

(table 1 anyfunc)
(export "table" (table 0))

So does this:

(table $0 1 anyfunc)
(export "table" (table $0))

Fixing that gives the following wabt error (you can try it here):

Error: validate failed:
0:0: error: type mismatch in if false branch, expected [i32] but got []

The missing location seems to be a wabt bug though. I have a WIP fix for that here. Applying this fix gives the error:

assemblyscript-310.wat:52:6: error: type mismatch in if false branch, expected [i32] but got []
     )
     ^

This is the if block referenced in the error:

     (if (result i32)
      ;;@ main.ts:5:16
      (i32.eq
       (get_local $0)
       ;;@ main.ts:5:23
       (i32.const 12)
      )
      ;;@ main.ts:6:23
      (i32.add
       (get_local $0)
       ;;@ main.ts:6:29
       (i32.const 32)
      )
      (block
       ;;@ main.ts:4:38
       (set_local $0
        (i32.add
         (get_local $0)
         (i32.const 1)
        )
       )
       (br $repeat|0)
      )
     )

The problem is that the if has an i32 result, but the block doesn't. To fix it you can change the block to:

(block (result i32)
   ...
)

This works.

[dcodeIO]

For reference, the original function body before optimizations looks like the following, so the type mismatch happens during optimization passes I think?

(func $main/testBreak (; 1 ;) (type $v)
  (local $0 i32)
  (local $1 i32)
  (set_local $0
   (i32.const 0)
  )
  (block $break|0
   (set_local $1
    (i32.const 0)
   )
   (loop $repeat|0
    (br_if $break|0
     (i32.eqz
      (i32.lt_s
       (get_local $1)
       (i32.const 32)
      )
     )
    )
    (if
     (i32.eq
      (get_local $1)
      (i32.const 12)
     )
     (block
      (set_local $0
       (i32.add
        (get_local $1)
        (i32.const 32)
       )
      )
      (br $break|0)
     )
    )
    (set_local $1
     (i32.add
      (get_local $1)
      (i32.const 1)
     )
    )
    (br $repeat|0)
   )
  )
  (if
   (i32.eqz
    (i32.eq
     (get_local $0)
     (i32.const 44)
    )
   )
   (block
    (call $~lib/env/abort
     (i32.const 0)
     (i32.const 8)
     (i32.const 10)
     (i32.const 8)
    )
    (unreachable)
   )
  )
 )

[kripken]

Thanks @binji - I misread $0 as 0, oops :) yeah, that's a binaryen printing bug. Fixed in the same PR, we just were not printing the table name.

[kripken]

The if issue is because binaryen has an unreachable type, which is used for one arm of that if, while wasm does not have that type.

To get wasm text that is valid wasm wat, you can replace --print with --generate-stack-ir --print-stack-ir, as stack IR is always valid wat. Added docs for this in WebAssembly/binaryen#1716