Monitoring Postfix

[gmacon]

I'd like to use the postfix_mailq built-in plugin to monitor my mail server, but it's not clear to me what the best approach for that is. I see there are options for adding smart and docker, but it looks like that requires manual intervention for every plugin you want to add. Is there a way to generically add plugins that aren't "local" plugins that I write in my Nix configuration?

[BenediktSeidl]

postfix_mailq is not a plugin but a built in section of the linux agent: https://github.com/Checkmk/checkmk/blob/7c69e8642aedee3d9656f2387d87ec12426cf89a/agents/check_mk_agent.linux#L944-L1033

i would say the currently problem is, that the postconf binary is not available: https://github.com/Checkmk/checkmk/blob/7c69e8642aedee3d9656f2387d87ec12426cf89a/agents/check_mk_agent.linux#L990 so adding the correct dependency to the nixos implementation of the checkmk agent would be a first step.

but i fear the way the checkmk agent figures out what queues are available is not compatible with nixos? the agent references /etc/postfix which will probably not exist on your system?!

i have no domain knowledge regarding postfix, so i don't know how to patch the agent to discover queues on a nixos based system.

can you share a minimal configuration how to setup postfix and a queue so it should be shown in the checkmk agent output? then maybe i can play around a bit and find a way to monitor this on nixos.

[gmacon]

Aha! Thanks! I was looking in the completely wrong place to try to fix this, and I got it working by adding postfix to systemd.services."check_mk_agent@".path.

Here's details on what I did:

Use this flake:

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
    checkmk = {
      url = "github:Checkmk/checkmk/v2.3.0p36";
      flake = false;
    };
    check_mk_agent = {
      url = "github:BenediktSeidl/nixos-check_mk_agent-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.checkmk.follows = "checkmk";
    };
  };
  outputs =
    { nixpkgs, check_mk_agent, ... }:
    {
      nixosConfigurations.test = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          check_mk_agent.nixosModules.check_mk_agent
          (
            { pkgs, ... }:
            {
              system.stateVersion = "25.11";
              services.check_mk_agent = {
                enable = true;
                bind = "0.0.0.0";
                openFirewall = true;
              };
              # Uncomment this line to fix it!
              # systemd.services."check_mk_agent@".path = [ pkgs.postfix ];
              services.postfix.enable = true;
              users.users.root.initialPassword = "root";
            }
          )
        ];
      };
    };
}

Start the VM by running:

nix build ".#nixosConfigurations.test.config.system.build.vm" && QEMU_NET_OPTS="hostfwd=tcp:127.0.0.1:6556-:6556" ./result/bin/run-nixos-vm

Then, in another terminal, query the agent:

echo | nc 127.0.0.1 6556 | grep -C3 postfix

If the fix line is uncommented, you will see a section like

<<<postfix_mailq>>>
[[[default]]]
QUEUE_deferred 4 0
QUEUE_active 4 0

in the output.