openABAP doesn't support the LOOP AT ... GROUP BY syntax

[jung-thomas]

Related to Exercism. Trying to use the LOOP AT ... GROUP BY syntax to solve an exercise. Here is an example the executes in an ABAP 7.51 and higher system but in open-abap produces a parsing error/ syntax error that there is no endloop.

CLASS zcl_itab_aggregation DEFINITION
  PUBLIC
  FINAL
  CREATE PUBLIC .

  PUBLIC SECTION.
    INTERFACES if_oo_adt_classrun.
    TYPES  group TYPE c LENGTH 1.
    TYPES: BEGIN OF initial_numbers_type,
             group  TYPE group,
             number TYPE i,
           END OF initial_numbers_type,
           initial_numbers TYPE STANDARD TABLE OF initial_numbers_type WITH EMPTY KEY.

    TYPES: BEGIN OF aggregated_data_type,
             group   TYPE group,
             count   TYPE i,
             sum     TYPE i,
             min     TYPE i,
             max     TYPE i,
             average TYPE f,
           END OF aggregated_data_type,
           aggregated_data TYPE STANDARD TABLE OF aggregated_data_Type WITH EMPTY KEY.

  PROTECTED SECTION.
  PRIVATE SECTION.
ENDCLASS.

CLASS zcl_itab_aggregation IMPLEMENTATION.
  METHOD if_oo_adt_classrun~main.
    DATA(initial_numbers) = VALUE initial_numbers(
        ( group = 'A' number = 10 )
        ( group = 'B' number = 5 )
        ( group = 'A' number = 6 )
        ( group = 'C' number = 22 )
        ( group = 'A' number = 13 )
        ( group = 'C' number = 500 )
    ).
    DATA aggregated_data TYPE aggregated_data.

    LOOP AT initial_numbers REFERENCE INTO DATA(initial_number)
       GROUP BY ( key = initial_number->group  count = GROUP SIZE )
       ASCENDING
       REFERENCE INTO DATA(group_key).

      APPEND INITIAL LINE TO aggregated_data REFERENCE INTO DATA(aggregated_item).
      aggregated_item->group = group_key->key.
      aggregated_item->count = group_key->count.
      aggregated_item->min = 9999999.
      LOOP AT GROUP group_key REFERENCE INTO DATA(group_item).
        aggregated_item->sum = aggregated_item->sum + group_item->number.
        aggregated_item->min = nmin( val1 = aggregated_item->min
                                     val2 = group_item->number ).
        aggregated_item->max = nmax( val1 = aggregated_item->max
                                     val2 = group_item->number ).
      ENDLOOP.
      aggregated_item->average = aggregated_item->sum / aggregated_item->count.
    ENDLOOP.

    out->write( initial_numbers ).
    out->write( aggregated_data ).

  ENDMETHOD.
ENDCLASS.

[larshp]

downport of GROUP BY to be implemented in abaplint

[larshp]

reduced to

TYPES: BEGIN OF initial_numbers_type,
         group  TYPE string,
         number TYPE i,
       END OF initial_numbers_type.
DATA initial_numbers TYPE STANDARD TABLE OF initial_numbers_type WITH DEFAULT KEY.
DATA row LIKE LINE OF initial_numbers.
row-group = 'A'.
row-number = 10.
INSERT row INTO TABLE initial_numbers.
row-group = 'A'.
row-number = 6.
INSERT row INTO TABLE initial_numbers.

LOOP AT initial_numbers REFERENCE INTO DATA(initial_number)
   GROUP BY ( key = initial_number->group  count = GROUP SIZE )
   ASCENDING
   REFERENCE INTO DATA(group_key).
  LOOP AT GROUP group_key REFERENCE INTO DATA(group_item).
    WRITE: / group_item->number, group_key->count.
  ENDLOOP.
  WRITE /.
ENDLOOP.

[larshp]

@jung-thomas try again, there are some variations of the GROUP BY that does not work yet, but above should now work

[jung-thomas]

I just tried the full sample again from Exercism but received the following error:

We received the following error when we ran your code:
generic[1, 1] - Error: void, generic at VoidType.toABAP (webpack://@abaplint/cli/./node_modules/@abaplint/core/build/src/abap/types/basic/void_type.js?:14:15) (generic_error) [E]
abaplint: 1 issue(s) found

[larshp]

try without if_oo_adt_classrun

[jung-thomas]

I tried it in a class/exercise that doesn't use the if_oo_adt_classrun and it fails with the same error. I tried your more simplified example of the LOOP AT ... GROUP BY and it passes. But my original example produces this "void, generic" error.

[larshp]

@jung-thomas whats the exact code,

I got the following, and it seems to run,

CLASS zcl_hello_world DEFINITION PUBLIC.
  PUBLIC SECTION.

    TYPES  group TYPE c LENGTH 1.
    TYPES: BEGIN OF initial_numbers_type,
             group  TYPE group,
             number TYPE i,
           END OF initial_numbers_type,
           initial_numbers TYPE STANDARD TABLE OF initial_numbers_type WITH EMPTY KEY.

    TYPES: BEGIN OF aggregated_data_type,
             group   TYPE group,
             count   TYPE i,
             sum     TYPE i,
             min     TYPE i,
             max     TYPE i,
             average TYPE f,
           END OF aggregated_data_type,
           aggregated_data TYPE STANDARD TABLE OF aggregated_data_Type WITH EMPTY KEY.

   METHODS hello RETURNING VALUE(result) TYPE string.
ENDCLASS.

CLASS zcl_hello_world IMPLEMENTATION.

  METHOD hello.

    DATA(initial_numbers) = VALUE initial_numbers(
        ( group = 'A' number = 10 )
        ( group = 'B' number = 5 )
        ( group = 'A' number = 6 )
        ( group = 'C' number = 22 )
        ( group = 'A' number = 13 )
        ( group = 'C' number = 500 )
    ).
    DATA aggregated_data TYPE aggregated_data.

    LOOP AT initial_numbers REFERENCE INTO DATA(initial_number)
       GROUP BY ( key = initial_number->group  count = GROUP SIZE )
       ASCENDING
       REFERENCE INTO DATA(group_key).

      APPEND INITIAL LINE TO aggregated_data REFERENCE INTO DATA(aggregated_item).
      aggregated_item->group = group_key->key.
      aggregated_item->count = group_key->count.
      aggregated_item->min = 9999999.
      LOOP AT GROUP group_key REFERENCE INTO DATA(group_item).
        aggregated_item->sum = aggregated_item->sum + group_item->number.
        aggregated_item->min = nmin( val1 = aggregated_item->min
                                     val2 = group_item->number ).
        aggregated_item->max = nmax( val1 = aggregated_item->max
                                     val2 = group_item->number ).
      ENDLOOP.
      aggregated_item->average = aggregated_item->sum / aggregated_item->count.
    ENDLOOP.

  ENDMETHOD.

ENDCLASS.

[jung-thomas]

Not sure what the void error was earlier. Maybe I had messed up my testing class somewhere else. I started with a clean class and tested it works now just fine. Thanks!