screen shaders

[flickowoa]

ability to hv a custom shader file apply to certain/all layers

eg: a grayscale shader that removes all color from screen

[MahouShoujoMivutilde]

As an nvidia user (yeah yeah, I know) - it will certainly be nice to have an ability to apply a blue light filter (even if it's going to be a custom shader).

[vaxerski]

added in 7b020ff

See an example in examples/screenShader.frag

[MahouShoujoMivutilde]

Thanks!

One thing I noticed is that if I:

1. ...set the shader
2. reload config (it'll apply as expected)
3. then comment out the screen_shader variable to unset it
4. and again reload config
   ...the screen will be compressed to a small line at the bottom of the monitor, the rest will be black.

(Just reloading to replace the shader works fine).

Log after commenting out and reloading (nothing seems to be abnormal)

[LOG] Reloading the config!
[LOG] Created a bezier curve, baked 200 points, mem usage: 3.20kB, time to bake: 28.12µs. Estimated average calc time: 0.01µs.
[LOG] ApplyConfigToKeyboard for "Power Button", hasconfig: 0
[LOG] Attempting to create a keymap for layout us with variant  (rules: , model: , options: )
[LOG] Set the keyboard layout to us and variant to  for keyboard "Power Button"
[LOG] ApplyConfigToKeyboard for "Power Button", hasconfig: 0
[LOG] Attempting to create a keymap for layout us with variant  (rules: , model: , options: )
[LOG] Set the keyboard layout to us and variant to  for keyboard "Power Button"
[LOG] ApplyConfigToKeyboard for "Logitech USB Keyboard", hasconfig: 1
[LOG] Attempting to create a keymap for layout us,ru with variant  (rules: , model: , options: caps:escape,grp:toggle)
[LOG] Set the keyboard layout to us,ru and variant to  for keyboard "Logitech USB Keyboard"
[LOG] ApplyConfigToKeyboard for "Logitech USB Keyboard Consumer Control", hasconfig: 0
[LOG] Attempting to create a keymap for layout us with variant  (rules: , model: , options: )
[LOG] Set the keyboard layout to us and variant to  for keyboard "Logitech USB Keyboard Consumer Control"
[LOG] ApplyConfigToKeyboard for "Logitech USB Keyboard System Control", hasconfig: 0
[LOG] Attempting to create a keymap for layout us with variant  (rules: , model: , options: )
[LOG] Set the keyboard layout to us and variant to  for keyboard "Logitech USB Keyboard System Control"
[LOG] ApplyConfigToKeyboard for "Eee PC WMI hotkeys", hasconfig: 0
[LOG] Attempting to create a keymap for layout us with variant  (rules: , model: , options: )
[LOG] Set the keyboard layout to us and variant to  for keyboard "Eee PC WMI hotkeys"
[LOG] Applied config to mouse Razer Razer DeathAdder, sens 0.00
[LOG] Applied config to mouse Logitech USB Keyboard Consumer Control, sens 0.00
[WARN] No rule found for DP-1, trying to use the first.
[WARN] No rule found for DP-1, trying to use the first.
[WARN] No rule found for DP-1, trying to use the first.
[LOG] Applying monitor rule for DP-1
[LOG] Setting preferred mode for DP-1
[LOG] Monitor DP-1 -> destroyed all render data
[LOG] LayerSurface ffba3f30 arranged: x: 0 y: 1396 w: 2560 h: 44 with margins: t: 0 l: 0 r: 0 b: 0
[LOG] LayerSurface 82f60 arranged: x: 0 y: 0 w: 2560 h: 1440 with margins: t: 0 l: 0 r: 0 b: 0
[LOG] Monitor DP-1 layers arranged: reserved: 0.000000 0.000000 0.000000 44.000000
[ERR] Error in getMonitorFromString: no such monitor
[LOG] LayerSurface ffba3f30 arranged: x: 0 y: 1396 w: 2560 h: 44 with margins: t: 0 l: 0 r: 0 b: 0
[LOG] LayerSurface 82f60 arranged: x: 0 y: 0 w: 2560 h: 1440 with margins: t: 0 l: 0 r: 0 b: 0
[LOG] Monitor DP-1 layers arranged: reserved: 0.000000 0.000000 0.000000 44.000000
[LOG] Framebuffer created, status 36053
[LOG] Framebuffer created, status 36053
[LOG] Framebuffer created, status 36053
[LOG] Framebuffer created, status 36053
[LOG] Allocated texture for BGTex
[LOG] Background created for monitor DP-1
[LOG] Shaders initialized successfully.
[LOG] Framebuffer created, status 36053
[LOG] Cleanup: destroyed a layersurface

BTW, if anyone is looking for something closer to f.lux - I am quite pleased with this:

// vim: set ft=glsl:
// blue light filter shader
// values from https://reshade.me/forum/shader-discussion/3673-blue-light-filter-similar-to-f-lux

precision mediump float;
varying vec2 v_texcoord;
uniform sampler2D tex;

void main() {

    vec4 pixColor = texture2D(tex, v_texcoord);

    // green
    pixColor[1] *= 0.855;

    // blue
    pixColor[2] *= 0.725;

    gl_FragColor = pixColor;
}

[MahouShoujoMivutilde]

EDIT nov. 2023, for Nvidia users:

Driver 545.29.02 implements GAMMA_LUT, so if you cared only about "night light" / "redshift" / "blue light filter" / etc and nothing more - gammastep now works.

It also has fade transition / sunset and sunrise calculation.

---

EDIT feb. 2024

See #1140 (comment) if text is blurry.

I don't see the problem yet, but I'm running 0.35.0 stable. mediump might be fine as long as the same is used internaly by Hyprland.

---

Blue light filter with variable color temperature:

precision highp float;
varying vec2 v_texcoord;
uniform sampler2D tex;

const float temperature = 2600.0;
const float temperatureStrength = 1.0;

#define WithQuickAndDirtyLuminancePreservation
const float LuminancePreservationFactor = 1.0;

// function from https://www.shadertoy.com/view/4sc3D7
// valid from 1000 to 40000 K (and additionally 0 for pure full white)
vec3 colorTemperatureToRGB(const in float temperature){
    // values from: http://blenderartists.org/forum/showthread.php?270332-OSL-Goodness&p=2268693&viewfull=1#post2268693
    mat3 m = (temperature <= 6500.0) ? mat3(vec3(0.0, -2902.1955373783176, -8257.7997278925690),
                                            vec3(0.0, 1669.5803561666639, 2575.2827530017594),
                                            vec3(1.0, 1.3302673723350029, 1.8993753891711275)) :
                                       mat3(vec3(1745.0425298314172, 1216.6168361476490, -8257.7997278925690),
                                            vec3(-2666.3474220535695, -2173.1012343082230, 2575.2827530017594),
                                            vec3(0.55995389139931482, 0.70381203140554553, 1.8993753891711275));
    return mix(
        clamp(vec3(m[0] / (vec3(clamp(temperature, 1000.0, 40000.0)) + m[1]) + m[2]), vec3(0.0), vec3(1.0)),
        vec3(1.0),
        smoothstep(1000.0, 0.0, temperature)
    );
}

void main() {
    vec4 pixColor = texture2D(tex, v_texcoord);

    // RGB
    vec3 color = vec3(pixColor[0], pixColor[1], pixColor[2]);

#ifdef WithQuickAndDirtyLuminancePreservation
    color *= mix(1.0,
                 dot(color, vec3(0.2126, 0.7152, 0.0722)) / max(dot(color, vec3(0.2126, 0.7152, 0.0722)), 1e-5),
                 LuminancePreservationFactor);
#endif

    color = mix(color, color * colorTemperatureToRGB(temperature), temperatureStrength);

    vec4 outCol = vec4(color, pixColor[3]);

    gl_FragColor = outCol;
}

[jiiiijiij]

could you make a shader file for grayscale eink like?

[ulziibuyan]

@jiiiijiij

//
// Example grayscale shader.
// 

precision mediump float;
varying vec2 v_texcoord;
uniform sampler2D tex;

void main() {
    vec4 pixColor = texture2D(tex, v_texcoord);

    gl_FragColor = vec4(
        pixColor[0] * 0.299 + pixColor[1] * 0.587 + pixColor[2] * 0.114,
        pixColor[0] * 0.299 + pixColor[1] * 0.587 + pixColor[2] * 0.114,
        pixColor[0] * 0.299 + pixColor[1] * 0.587 + pixColor[2] * 0.114,
        pixColor[3]
    );
}

[jiiiijiij]

@ulziibuyan thank you, you save me eyes

[jackunity69]

Does anybody have vibrance shader file? I tried to make vibrance shader file from kwin-effect-shaders but I cant get it to work. Here's the code

#if VIBRANCE_ENABLED == 1
/**
Vibrance
by Christian Cann Schuldt Jensen ~ CeeJay.dk

Vibrance intelligently boosts the saturation of pixels so pixels that had little color get a larger boost than pixels that had a lot.
This avoids oversaturation of pixels that were already very saturated.
History:
Version 1.0 by Ceejay.dk

• Original
  Version 1.1 by CeeJay.dk
• Introduced RBG balance to help colorblind users
  Version 1.1.1
• Minor UI improvements for Reshade 3.x

Ported to glsl by kevinlekiller - 2022
*/

#if VIB_LUMA == 1
vec3 VIB_coefLuma = vec3(0.333333, 0.333334, 0.333333);
#else
vec3 VIB_coefLuma = vec3(0.212656, 0.715158, 0.072186);
#endif
vec3 VIB_coeffVibrance = vec3(VIB_RGB_BALANCE * -VIB_VIBRANCE);

void shader_vibrance() {
float luma = dot(VIB_coefLuma, g_Color.rgb);
float max_color = max(g_Color.r, max(g_Color.g, g_Color.b));
float min_color = min(g_Color.r, min(g_Color.g, g_Color.b));
float color_saturation = max_color - min_color;
vec3 p_col = vec3(vec3(vec3(vec3(sign(VIB_coeffVibrance) * color_saturation) - 1.0) * VIB_coeffVibrance) + 1.0);
g_Color.r = mix(luma, g_Color.r, p_col.r);
g_Color.g = mix(luma, g_Color.g, p_col.g);
g_Color.b = mix(luma, g_Color.b, p_col.b);
}
#endif // VIBRANCE_ENABLED

[MahouShoujoMivutilde]

Here.

// vibrance for hyprland

precision mediump float;
varying vec2 v_texcoord;
uniform sampler2D tex;

// see https://github.com/CeeJayDK/SweetFX/blob/a792aee788c6203385a858ebdea82a77f81c67f0/Shaders/Vibrance.fx#L20-L30
const vec3 VIB_RGB_BALANCE = vec3(1.0, 1.0, 1.0);
const float VIB_VIBRANCE = 0.15;


const vec3 VIB_coeffVibrance = VIB_RGB_BALANCE * -VIB_VIBRANCE;

void main() {

    vec4 pixColor = texture2D(tex, v_texcoord);

    // RGB
    vec3 color = vec3(pixColor[0], pixColor[1], pixColor[2]);


    // vec3 VIB_coefLuma = vec3(0.333333, 0.333334, 0.333333); // was for `if VIB_LUMA == 1`
    vec3 VIB_coefLuma = vec3(0.212656, 0.715158, 0.072186); // try both and see which one looks nicer.

    float luma = dot(VIB_coefLuma, color);

    float max_color = max(color[0], max(color[1], color[2]));
    float min_color = min(color[0], min(color[1], color[2]));

    float color_saturation = max_color - min_color;

    vec3 p_col = vec3(vec3(vec3(vec3(sign(VIB_coeffVibrance) * color_saturation) - 1.0) * VIB_coeffVibrance) + 1.0);

    pixColor[0] = mix(luma, color[0], p_col[0]);
    pixColor[1] = mix(luma, color[1], p_col[1]);
    pixColor[2] = mix(luma, color[2], p_col[2]);

    gl_FragColor = pixColor;
}

Seems to be working, check out the link to see acceptable config values ranges.

EDIT:

Apparently, shaders now are invisible on screenshots on the latest master. Welp. Try it.

Also, tested and

vec3 VIB_coefLuma = vec3(0.212656, 0.715158, 0.072186);

looks a bit better, and also is the one that is used in original.

[jackunity69]

@MahouShoujoMivutilde Thank you!