Install-Style-Bert-VITS2.batでインストールが出来ない事象とその解決方法

[milmil22010718]

素晴らしいソフトウェアを提供していただきありがとうございます。
Style-Bert-VITS2が動作しなくなった経緯とその解決方法を共有いたします。

動作しなくなった経緯

2025年10月14日にUpdate-Style-Bert-VITS2.batでアップデートしたところ、起動しなくなりました。（それ以前は問題なく動作しておりました）
環境を再構築しようと考えて、新規にInstall-Style-Bert-VITS2.batを使用してインストールを実行しようとしたら下記のエラーが発生し、バッチ処理が停止いたしました。

Using Python 3.10.11 environment at: venv x Failed to build av==10.0.0

その後、問題解決のため、当方で調査いたしましたところ、torch、torchaudio、soxr、accelerate、gradio、CUDAを再インストールとバージョンアップが必要なことがわかりました。

解決方法

下記を再インストールとバージョンアップしたところ、音声生成と音声学習まで実行できるようになりましたので、共有いたします。

• 元々当方の環境でインストールされていたCUDA 11.3 を アンインストール後、CUDA 11.8をインストール
• Install-Style-Bert-VITS2.batとrequirements.txtを書き換えて、"torch==2.6.0" "torchaudio==2.6.0"をインストール。uv pip install "torch==2.6.0" "torchaudio==2.6.0" --index-url https://download.pytorch.org/whl/cu118　Install-Style-Bert-VITS2.batでtorch、torchaudioをインストールしても、requirements.txtで古いバージョンのtorch、torchaudioがインストールされてしまうため、requirements.txtのtorch、torchaudioの行を消す。
• Install-Style-Bert-VITS2.batを書き換えてgradio==5.34.0がインストールされるようにする。issue209でも指摘がありましたとおり、このバージョンでないとapp.batの実行時に真っ白な画面になります。uv pip install gradio==5.34.0
• Style-Bert-VITS2のフォルダ内でPowerShellを起動し、venv\Scripts\activateとset USE_LIBUV=0を実行。
• requirements.txtの末尾にsoxrとaccelerateを追記し、両方をインストール。
• 学習画面の学習タブで学習を開始するをクリックするとエラーになるので、train_ms_jp_extra.pyの135行目をinit_method="env://?use_libuv=0"に変更。

以上で問題が解決しました。

当方が実施したこと

1.まず、CUDA 11.3 を アンインストール後、CUDA 11.8をインストール
2.Install-Style-Bert-VITS2.batを実施。上述したエラーで停止する。
3.次に、Style-Bert-VITS2のrequirements.txtを下記のように修正して保存。

g2p_en
GPUtil
gradio>=4.32
jieba
librosa==0.9.2
loguru
nltk<=3.8.1
num2words
numpy<2
onnx
onnxconverter-common
onnxruntime
onnxruntime-directml; sys_platform == 'win32'
onnxruntime-gpu; sys_platform != 'darwin'
onnxsim-prebuilt
protobuf==4.25
psutil
punctuators
pyannote.audio>=3.1.0
pyloudnorm
pyopenjtalk-dict
pypinyin
pyworld-prebuilt
stable_ts
tensorboard
transformers
umap-learn
soxr
accelerate

4.Style-Bert-VITS2の一つ上のフォルダ下記の通り修正したInstall-Style-Bert-VITS2.bat(Install-Style-Bert-VITS2_.bat等に名前を修正しておく)を実施。
（途中で黒画面に出てくる２回の質問はYを入力してEnter）

chcp 65001 > NUL
@echo off

@REM エラーコードを遅延評価するために設定
setlocal enabledelayedexpansion

@REM PowerShellのコマンド
set PS_CMD=PowerShell -Version 5.1 -ExecutionPolicy Bypass

@REM PortableGitのURLと保存先
set DL_URL=https://github.com/git-for-windows/git/releases/download/v2.44.0.windows.1/PortableGit-2.44.0-64-bit.7z.exe
set DL_DST=%~dp0lib\PortableGit-2.44.0-64-bit.7z.exe

@REM Style-Bert-VITS2のリポジトリURL
set REPO_URL=https://github.com/litagin02/Style-Bert-VITS2

@REM カレントディレクトリをbatファイルのディレクトリに変更
pushd %~dp0

@REM lib フォルダがなければ作成
if not exist lib\ ( mkdir lib )

echo --------------------------------------------------
echo PS_CMD: %PS_CMD%
echo DL_URL: %DL_URL%
echo DL_DST: %DL_DST%
echo REPO_URL: %REPO_URL%
echo --------------------------------------------------
echo.
echo --------------------------------------------------
echo Checking Git Installation...
echo --------------------------------------------------
echo Executing: git --version
git --version

@REM Pythonのセットアップ
echo --------------------------------------------------
echo Setting up Python environment...
echo --------------------------------------------------
echo Executing: call Setup-Python.bat ".\lib\python" ".\Style-Bert-VITS2\venv"
call Setup-Python.bat ".\lib\python" ".\Style-Bert-VITS2\venv"
if !errorlevel! neq 0 ( popd & exit /b !errorlevel! )

@REM Style-Bert-VITS2フォルダに移動
pushd Style-Bert-VITS2

@REM 後で消す！！！！！！！！！！
@REM git checkout dev
@REM 後で消す！！！！！！！！！！

echo --------------------------------------------------
echo Activating the virtual environment...
echo --------------------------------------------------
echo Executing: call ".\venv\Scripts\activate.bat"
call ".\venv\Scripts\activate.bat"
if !errorlevel! neq 0 ( popd & exit /b !errorlevel! )

echo --------------------------------------------------
echo Installing package manager uv...
echo --------------------------------------------------
echo Executing: pip install uv
pip install uv
if !errorlevel! neq 0 ( pause & popd & exit /b !errorlevel! )

pip uninstall torch torchaudio

echo --------------------------------------------------
echo Installing PyTorch...
echo --------------------------------------------------
@REM echo Executing: uv pip install "torch==2.6.0" "torchaudio<2.4" --index-url https://download.pytorch.org/whl/cu118
uv pip install "torch==2.6.0" "torchaudio==2.6.0" --index-url https://download.pytorch.org/whl/cu118
if !errorlevel! neq 0 ( pause & popd & exit /b !errorlevel! )

echo ----------------------------------------
echo Environment setup is complete. Start downloading the model.
echo ----------------------------------------
echo Executing: python initialize.py
python initialize.py

echo --------------------------------------------------
echo Installing other dependencies...
echo --------------------------------------------------
echo Executing: uv pip install -r requirements.txt
uv pip install -r requirements.txt
if !errorlevel! neq 0 ( pause & popd & exit /b !errorlevel! )

uv pip install gradio==5.34.0

echo ----------------------------------------
echo Model download is complete. Start Style-Bert-VITS2 Editor.
echo ----------------------------------------
echo Executing: python server_editor.py --inbrowser
python server_editor.py --inbrowser
pause

popd

popd

endlocal

5.Style-Bert-VITS2のフォルダ内でPowerShellを起動し、

venv\Scripts\activate
set USE_LIBUV=0

を実行。

6.train_ms_jp_extra.pyの135行目をinit_method="env://?use_libuv=0"に修正。

以上です。
お忙しい所、恐れ入りますが、お役に立てれば幸いです。
よろしくお願いいたします。

[ganpare]

ありがとうございます！
久しぶりに学習しようとしたらはまりましたが無事解決できました