get denote link in org-capture template with %a expansion

[jarofromel]

Hello,
is there please a way of getting denote link in org-capture template with %a expansion?
When I am in the denote buffer and call org-capture, the %a expands to file or org-id type of link (file: or id:).

This should be done by org-store-link that is implicitly called in the call of org-capture.
But in the case of denote, the handler (denote-link-ol-store) is called only if it is was invoked interactively so the denote link is not created.

denote/denote.el

Line 6912 in e6f6111

(defun denote-link-ol-store (&optional interactive?)

[protesilaos]

Hello @jarofromel!

is there please a way of getting denote link in org-capture template with %a expansion?

This should happen by default. Something must be wrong. I will look into it tonight.

[protesilaos]

Can you try this?

(defun denote-link-ol-store (&optional _interactive?)
  "Handler for `org-store-link' adding support for denote: links.
Optional INTERACTIVE? is used by `org-store-link'.

Also see the user option `denote-org-store-link-to-heading'."
  (when-let* ((file (buffer-file-name))
              ((file-regular-p file))
              ((denote-file-is-in-denote-directory-p file))
              ((denote-file-has-denoted-filename-p file))
              (file-id (denote-retrieve-filename-identifier file))
              (description (denote-get-link-description file)))
    (let ((heading-links (and denote-org-store-link-to-heading
                              (derived-mode-p 'org-mode)
                              (denote--org-capture-link-specifiers-p)))
          (heading (denote-link-ol-get-heading)))
      (org-link-store-props
       :type "denote"
       :description (if (and heading-links heading)
                        (denote-link-format-heading-description
                         description
                         heading)
                      description)
       :link (cond
              ((when-let* ((id (org-entry-get (point) "CUSTOM_ID")))
                 (format "denote:%s::#%s" file-id id)))
              ((and heading-links (eq denote-org-store-link-to-heading 'context) heading)
               (format "denote:%s::*%s" file-id heading))
              ((and heading-links heading)
               (format "denote:%s::#%s" file-id (denote-link-ol-get-id)))
              (t
               (concat "denote:" file-id))))
      org-store-link-plist)))

I basically removed the test for interactive?. I need to review how Org uses that internally.

[jarofromel]

It works.
Checked with denote-org-store-link-to-heading set to nil|'context|'id and it works as intended, eg. %a is expanded to denote_id | denote_id+headline | denote_id+custom_id
Thanks a lot

[protesilaos]

I just committed the change. Thank you!