showmenu and dictionary don't mix well, how?

[euclidaeun]

Hi, I’m trying to use a StringDictionary with ShowMenu for NPC dialogue.

Example:

firsttime {
  this.options = NewStringDictionary()
  dictionary add (this.options, "getthing", "fish: Get the thing")
  dictionary add (this.options, "jump", "fish: Jump as high as you can")
  dictionary add (this.options, "vomit", "fish: Try to vomit the poison up")
}
game.talking_target = this
ShowMenu ("Choose", game.talking_target.options, false) {
  // add coding that retrieves the value of key from chosen options.
  // No matter how many questions there are, this coding here is only one line which saves lots of time.
  msg (""+StringDictionaryItem(game.talking_target.options, result))
  // if dictionary works, we can also do advanced automatic stuffs like auto deleting spoken conversations
  dictionary remove (game.talking_target.options, result)
}

Dictionary documentation:
https://docs.textadventures.co.uk/quest/using_dictionaries.html

Pixie's conversations:
https://github.com/ThePix/quest/wiki/Library:-Conversations

Observation:
I am noticing showmenu switches dictionary key and value the wrong way.

Why not list?:
I know you can use list to make a conversational npc,
but if dictionary works, the code is much lesser,
since list requires if result = , then msg,
while dictionary only needs one line of coding like retrieve msg result(key)

p.s. I am flexible, if there are other simpler ways that reduces lots of coding in npc dialogues, I can switch to that.
I just don't wanna use coding I don't understand and can't modify like Pixie's library or anyone's libraries, I know they works.

test27.zip

[Pertex]

where are your object’s script attributes?
if you use

      firsttime {
        msg ("https://docs.textadventures.co.uk/quest/using_dictionaries.html<br/>example, not working<br/><br/>")
      }
      options = NewStringDictionary()
      dictionary add (options, "getthing", "Get the thing")
      dictionary add (options, "jump", "Jump as high as you can")
      dictionary add (options, "vomit", "Try to vomit the poison up")
      ShowMenu ("Choose", options, false) {
        msg(result)
        do (player, result)
      }
    ]]></enter>

the player object needs the scripts getthing, jump and vomit

    <object name="player">
      <inherit name="editor_object" />
      <inherit name="editor_player" />
      <jump type="script"><![CDATA[
      msg(this.name + " is jumping")
      ]]>
      </jump>
<getthing type="script"><![CDATA[
     ...
      ]]>
      </getthing>
     ...
    </object>

[euclidaeun]

https://docs.textadventures.co.uk/quest/using_dictionaries.html
Not working example is now fixed by adding Pertex's solution of adding script attributes into player.

    <object name="player">
      <inherit name="editor_object" />
      <inherit name="editor_player" />
      <getthing type="script">
        msg (this.name+" got the thing")
      </getthing>
      <jump type="script">
        msg (this.name+" is jumping")
      </jump>
      <vomit type="script">
        msg (this.name+" vomited out the thing.")
      </vomit>
    </object>

However, this means every single question needs to add a player's attribute which is more workload than list conversation which is more workload than dictionary conversation, so I still think we need to head towards making dictionary conversation possible.

test27b.zip

[Pertex]

Sorry, but I don't get it. What can a string dictionary do that a string list can't? In a conversation, you want to give the player several options to choose from. There need to be scripts associated with these options that return a response. There are several ways to do this. Which one do you want to use?

[euclidaeun]

The bot accidentally and finally gave me a working code while I was trying to ask it to explain to you why dictionary conversation requires less player's chore

test27c.zip

dictionary conversation (working at room 5)

firsttime {
  this.actions = NewStringDictionary()
  dictionary add (this.actions, "getthing", "clock: Get the thing")
  dictionary add (this.actions, "jump", "clock: Jump as high as you can")
  dictionary add (this.actions, "vomit", "clock: Try to vomit the poison up")
  dictionary add (this.actions, "run", "clock: Run away quickly")
  dictionary add (this.actions, "hide", "clock: Find a place to hide")
  dictionary add (this.actions, "scream", "clock: Scream for help")
  dictionary add (this.actions, "cry", "clock: Break down crying")
  dictionary add (this.actions, "sleep", "clock: Try to sleep it off")
  dictionary add (this.actions, "attack", "clock: Attack blindly")
  dictionary add (this.actions, "defend", "clock: Brace for impact")
  dictionary add (this.actions, "inspect", "clock: Look closely at surroundings")
  dictionary add (this.actions, "wait", "clock: Do nothing and wait")
}
game.talking_target = this
options = NewStringList()
foreach (key, this.actions) {
  list add (options, key)
}
ShowMenu ("Choose", options, false) {
  msg (DictionaryItem (game.talking_target.actions, result))
  dictionary remove (game.talking_target.actions, result)
}

list conversation

options = NewStringList()
list add (options, "getthing")
list add (options, "jump")
list add (options, "vomit")
list add (options, "run")
list add (options, "hide")
list add (options, "scream")
list add (options, "cry")
list add (options, "sleep")
list add (options, "attack")
list add (options, "defend")
list add (options, "inspect")
list add (options, "wait")

ShowMenu ("Choose", options, false) {
  if (result = "getthing") {
    msg ("clock: Get the thing")
  }
  if (result = "jump") {
    msg ("clock: Jump as high as you can")
  }
  if (result = "vomit") {
    msg ("clock: Try to vomit the poison up")
  }
  if (result = "run") {
    msg ("clock: Run away quickly")
  }
  if (result = "hide") {
    msg ("clock: Find a place to hide")
  }
  if (result = "scream") {
    msg ("clock: Scream for help")
  }
  if (result = "cry") {
    msg ("clock: Break down crying")
  }
  if (result = "sleep") {
    msg ("clock: Try to sleep it off")
  }
  if (result = "attack") {
    msg ("clock: Attack blindly")
  }
  if (result = "defend") {
    msg ("clock: Brace for impact")
  }
  if (result = "inspect") {
    msg ("clock: Look closely at surroundings")
  }
  if (result = "wait") {
    msg ("clock: Do nothing and wait")
  }
}

Based on the player typing zone, dictionary conversation is easier to search, link and type both questions and answers.

[Pertex]

But is it enough to just display a message? Or shouldn't you instead call a script for each item to process the input?

[euclidaeun]

I am trying to make NPC dialogue so it is enough for me.

But for other game creators, a script output are better like adding item to inventory in addition to npc's dialogue.
Hence, I agree with you most game creators can just use list conversation to have that script output.

Or are you saying you can upgrade my dictionary conversation into calling scripts? If so, let me know.

[Pertex]

Oh you did it before. Just two ways to do it:

    <object name="talking_robot">
      <inherit name="editor_object" />
      <useindividualverblist />
      <speak type="script">
        firsttime {
          this.actions = NewStringDictionary()
          dictionary add (this.actions, "getthing", "Get the thing")
          dictionary add (this.actions, "jump", "Jump as high as you can")
          dictionary add (this.actions, "vomit", "Try to vomit the poison up")
          dictionary add (this.actions, "run", "Run away quickly")
          dictionary add (this.actions, "hide", "Find a place to hide")
          dictionary add (this.actions, "scream", "Scream for help")
          dictionary add (this.actions, "cry", "Break down crying")
          dictionary add (this.actions, "sleep", "Try to sleep it off")
          dictionary add (this.actions, "attack", "Attack blindly")
          dictionary add (this.actions, "defend", "Brace for impact")
          dictionary add (this.actions, "inspect", "Look closely at surroundings")
          dictionary add (this.actions, "wait", "Do nothing and wait")
        }
        game.talking_target = this
        options = NewStringList()
        foreach (key, this.actions) {
          list add (options, key)
        }
        ShowMenu ("Choose", options, false) {
          do (game.talking_target, result)
          // or
          actionfunction (game.talking_target, result)
          dictionary remove (game.talking_target.actions, result)
        }
      </speak>
      <jump type="script">
        msg ("jump")
      </jump>
    </object>
  </object>
  <function name="actionfunction" parameters="obj, command">
	msg(obj.name + " " + command)  
  </function>

[euclidaeun]

Your code works but it requires me to write 12 object's scripts which is what I am trying to avoid.

I am making a large game, it will have at least 20 dialogue npcs, and each npc would have at least 10 dialogues, that means I have to code in 200 object's scripts just for that dialogue npc part of my game and my game still have many other stuffs needs to be coded in.

This code is what I had expected, the bot gave it to me, but as you can see, the script failed to load,
possibly due to syntax error.

firsttime {
  this.actions = NewScriptDictionary()
  dictionary add (this.actions, "getthing", {
    msg ("clock: Get the thing")
  }
  )
  dictionary add (this.actions, "jump", {
    msg ("clock: Jump as high as you can")
  }
  )
  dictionary add (this.actions, "vomit", {
    msg ("clock: Try to vomit the poison up")
  }
  )
  dictionary add (this.actions, "run", {
    msg ("clock: Run away quickly")
  }
  )
  dictionary add (this.actions, "hide", {
    msg ("clock: Find a place to hide")
  }
  )
  dictionary add (this.actions, "scream", {
    msg ("clock: Scream for help")
  }
  )
  dictionary add (this.actions, "cry", {
    msg ("clock: Break down crying")
  }
  )
  dictionary add (this.actions, "sleep", {
    msg ("clock: Try to sleep it off")
  }
  )
  dictionary add (this.actions, "attack", {
    msg ("clock: Attack blindly")
  }
  )
  dictionary add (this.actions, "defend", {
    msg ("clock: Brace for impact")
  }
  )
  dictionary add (this.actions, "inspect", {
    msg ("clock: Look closely at surroundings")
  }
  )
  dictionary add (this.actions, "wait", {
    msg ("clock: Do nothing and wait")
  }
  )
}
game.talking_target = this
options = NewStringList()
foreach (key, this.actions) {
  list add (options, key)
}
ShowMenu ("Choose", options, false) {
  do (DictionaryItem(game.talking_target.actions, result))
}

From my observation, Quest is converting {} into () if you rewrite "dictionary add" into one line, and this seems to be breaking the script execution.

dictionary add (this.actions, "jump", {msg ("clock: Jump as high as you can")})

The last code of line failed to load too, and the bot completely avoids any discussion about it, lol

  do (DictionaryItem(game.talking_target.actions, result))

[KVonGit]

Hello. =)

To make that work:

firsttime {
  this.actions = NewScriptDictionary()
  this_script => {
    msg ("clock: Get the thing")
  }
  dictionary add (this.actions, "getthing", this_script)
  this_script => {
    msg ("clock: Jump as high as you can")
  }
  dictionary add (this.actions, "jump", this_script)
  this_script => {
    msg ("clock: Try to vomit the poison up")
  }
  dictionary add (this.actions, "vomit", this_script)
  this_script => {
    msg ("clock: Run away quickly")
  }
  dictionary add (this.actions, "run", this_script)
  this_script => {
    msg ("clock: Find a place to hide")
  }
  dictionary add (this.actions, "hide", this_script)
  this_script => {
    msg ("clock: Scream for help")
  }
  dictionary add (this.actions, "scream", this_script)
  this_script => {
    msg ("clock: Break down crying")
  }
  dictionary add (this.actions, "cry", this_script)
  this_script => {
    msg ("clock: Try to sleep it off")
  }
  dictionary add (this.actions, "sleep", this_script)
  this_script => {
    msg ("clock: Attack blindly")
  }
  dictionary add (this.actions, "attack", this_script)
  this_script => {
    msg ("clock: Brace for impact")
  }
  dictionary add (this.actions, "defend", this_script)
  this_script => {
    msg ("clock: Look closely at surroundings")
  }
  dictionary add (this.actions, "inspect", this_script)
  this_script => {
    msg ("clock: Do nothing and wait")
  }
  dictionary add (this.actions, "wait", this_script)
}
game.talking_target = this
options = NewStringList()
foreach (key, this.actions) {
  list add (options, key)
}
game.temporary_this = this
ShowMenu ("Choose", options, false) {
  invoke (ScriptDictionaryItem(game.talking_target.actions, result), QuickParams("this",game.temporary_this))
  game.temporary_this = null
}

---

I tested this, and everything seems to work.

[euclidaeun]

This KV's solution A is what I am looking for and will be using

For the benefit of other beginner coders, I added some upgrades:

1. Added cancel to avoid 0 conversations left stuck glitch.
2. Added 'add to player inventory' for 'jump' as script demonstration.
3. Auto delete dictionary entry after speaking about that topic.

firsttime {
  this.actions = NewScriptDictionary()
  this_script => {
    msg ("clock: Get the thing")
  }
  dictionary add (this.actions, "getthing", this_script)
  this_script => {
    msg ("fridge: I am jumping onto you!")
    AddToInventory (this)
  }
  dictionary add (this.actions, "jump", this_script)
  this_script => {
    msg ("clock: Try to vomit the poison up")
  }
  dictionary add (this.actions, "vomit", this_script)
  this_script => {
    msg ("clock: Run away quickly")
  }
  dictionary add (this.actions, "run", this_script)
  this_script => {
    msg ("clock: Find a place to hide")
  }
  dictionary add (this.actions, "hide", this_script)
  this_script => {
    msg ("clock: Scream for help")
  }
  dictionary add (this.actions, "scream", this_script)
  this_script => {
    msg ("clock: Break down crying")
  }
  dictionary add (this.actions, "cry", this_script)
  this_script => {
    msg ("clock: Try to sleep it off")
  }
  dictionary add (this.actions, "sleep", this_script)
  this_script => {
    msg ("clock: Attack blindly")
  }
  dictionary add (this.actions, "attack", this_script)
  this_script => {
    msg ("clock: Brace for impact")
  }
  dictionary add (this.actions, "defend", this_script)
  this_script => {
    msg ("clock: Look closely at surroundings")
  }
  dictionary add (this.actions, "inspect", this_script)
  this_script => {
    msg ("clock: Do nothing and wait")
  }
  dictionary add (this.actions, "wait", this_script)
  // ✅ CANCEL (persistent safe exit option)
  cancel_script => {
    msg ("You decide to step away for now.")
  }
  dictionary add (this.actions, "cancel", cancel_script)
}
game.talking_target = this
options = NewStringList()
foreach (key, this.actions) {
  list add (options, key)
}
game.temporary_this = this
ShowMenu ("Choose", options, false) {
  invoke (ScriptDictionaryItem(game.talking_target.actions, result), QuickParams("this", game.temporary_this))
  // ❗ only remove non-cancel actions
  if (not result = "cancel") {
    dictionary remove (game.talking_target.actions, result)
  }
  game.temporary_this = null
}

[KVonGit]

Just playing around with things we could do with ShowMenu... Here is a little test game with a few different approaches.

Mainly, when you SPEAK TO someone, it will display a menu with all the ASK, TELL, and ORDER (tellto) options for the object.

<!--Saved by Quest 5.9.9166.36226-->
<asl version="580">
  <include ref="English.aslx" />
  <include ref="Core.aslx" />
  <game name="ShowMenu Shennanigans">
    <gameid>9493ef09-5ef6-4b0f-9418-180a35f16534</gameid>
    <version>0.1 alpha</version>
    <firstpublished>2026</firstpublished>
    <feature_asktell />
    <start type="script"><![CDATA[
      frog.hop => {
        msg ("The frog hops in place.")
      }
      frog.ribbit => {
        msg ("The frog ribbits.")
      }
      game.statusattributes = NewStringDictionary()
      dictionary add (game.statusattributes, "moves", "Moves: !")
      game.moves = 0
    ]]></start>
  </game>
  <object name="room">
    <inherit name="editor_room" />
    <object name="player">
      <inherit name="editor_object" />
      <inherit name="editor_player" />
    </object>
    <object name="frog">
      <inherit name="editor_object" />
      <takemsg>{random:It's too slippery.:It hops out of reach before you can get it.:{=CapFirst(GetDefiniteName(frog))} might not like that.}</takemsg>
      <speak type="script"><![CDATA[
        SuppressTurnscripts
        opts = NewStringList()
        if (HasAttribute (this, "ask")) {
          foreach (key, this.ask) {
            list add (opts, "Ask " + GetDefiniteName(this) + " about " + StringListItem(Split(key, " "), 0) + "")
          }
        }
        if (HasAttribute (this, "tell")) {
          foreach (key, this.tell) {
            list add (opts, "Tell " + GetDefiniteName(this) + " about " + StringListItem(Split(key, " "), 0) + "")
          }
        }
        if (HasAttribute (this, "tellto")) {
          foreach (key, this.tellto) {
            list add (opts, "Tell " + GetDefiniteName(this) + " to " + StringListItem(Split(key, " "), 0) + "")
          }
        }
        ShowMenu ("OPTIONS:", opts, false) {
          msg (">> " + LCase(result))
          HandleSingleCommand (result)
        }
      ]]></speak>
      <tellto type="scriptdictionary">
        <item key="hop">
          msg (CapFirst(GetDefiniteName(this)) + " hops in place.")
        </item>
        <item key="jump">
          invoke (ScriptDictionaryItem(this.tellto, "hop"), QuickParams("this",this))
        </item>
        <item key="ribbit speak talk">
          msg ("The frog says, \"ribbit!\"")
        </item>
      </tellto>
      <ask type="scriptdictionary">
        <item key="lillypads">
          msg ("The frog seems happy to talk about lillypads. \"Ribbit,\" says the frog, as if to confirm this.")
        </item>
      </ask>
    </object>
  </object>
  <command name="v_test">
    <pattern>test</pattern>
    <script><![CDATA[
      SuppressTurnscripts
      testdic = NewStringDictionary()
      dictionary add (testdic, "x me", "Examine yourself.")
      dictionary add (testdic, "jump", "Jump in place.")
      if (frog.parent = game.pov.parent) {
        dictionary add (testdic, "x frog", "Get a good look at the frog.")
      }
      ShowMenu ("Choose a command.", testdic, false) {
        msg (">> " + LCase(result))
        HandleSingleCommand (result)
      }
    ]]></script>
  </command>
  <turnscript name="ts_test">
    <enabled />
    <script>
      if (not HasAttribute (game, "moves")) {
        game.moves = 0
      }
      game.moves = game.moves + 1
    </script>
  </turnscript>
</asl>

[euclidaeun]

This KV's solution B will be more popular as it have high functionality while only needing to click checkbox of game object's features tab of ask/tell, completely skipping the installing and learning the conversational library process.

1. The autobuild conversation menu by KV allows direct usage of ask/tell features.
2. Ask/tell features have many functions like script + dialogue, script/hint to tell if asked about unknown topic.
3. Ask/tell is more intuitive and organized with ask, tell, tell to sections.
4. In comparison to script dictionary conversation which can easily break if typo, this method is far more stable.

[KVonGit]

I won't play with this anymore after this, I promise. (;

... but here's one last example game, with yet another approach.

It works. It's not as good as just using HandleSingleCommand to do pretty much the same thing, but something in the code might be helpful, maybe.

<!--Saved by Quest 5.9.9166.36226-->
<asl version="580">
  <include ref="English.aslx" />
  <include ref="Core.aslx" />
  <game name="Even More ShowMenu Shennanigans">
    <gameid>97e08b9f-ff58-4665-972c-4ceed264af45</gameid>
    <version>1.0</version>
    <firstpublished>2026</firstpublished>
  </game>
  <object name="room">
    <inherit name="editor_room" />
    <object name="player">
      <inherit name="editor_object" />
      <inherit name="editor_player" />
      <object name="frob">
        <inherit name="editor_object" />
	    <take />
      </object>
    </object>
    <object name="box">
      <inherit name="editor_object" />
      <inherit name="container_closed" />
      <feature_container />
      <listchildren />
      <isopen />
    </object>
  </object>
  <command name="v_test">
    <pattern>test</pattern>
    <script><![CDATA[
      dic = NewStringDictionary()
      dictionary add (dic, "jump", "Try jumping.")
      dictionary add (dic, "lookat|object=player", "Try examining yourself.")
      dictionary add (dic, "put|object1=frob,object2=box", "Try putting the frob in the box.")
      ShowMenu ("CHOOSE!", dic, false) {
        if (Instr(result, "|") > 0) {
          parts = Split(result,"|")
          cmd = GetObject (StringListItem (parts, 0))
          dicstuff = StringListItem(parts,1)
          qdic = NewDictionary()
          foreach (pair, Split(dicstuff, ",")) {
            key_entry = Split(pair, "=")
            key = StringListItem (key_entry,0)
            entry = GetObject (StringListItem (key_entry, 1))
            if (entry = null) {
              entry = StringListItem (key_entry, 1)
              if (entry = "game.pov") {
                entry = game.pov
              }
            }
            dictionary add (qdic, key, entry)
          }
          invoke (cmd.script, qdic)
        }
        else {
          cmd = GetObject(result)
          invoke (cmd.script)
        }
      }
    ]]></script>
  </command>
</asl>

[Pertex]

wouldn't this be shorter?

dictionary add (dic, "lookat|player", "Try examining yourself.")
dictionary add (dic, "put|frob,box", "Try putting the frob in the box.")