Archlinux PKGBUILD fix

[ManuLinares]

I fixed the archlinux AUR PKGBUILD

• Changed in "build()" --frozen to --locked, as it needs to download packages, and frozen prevents it.
• Removed from "package()" cargo install, because this forces a rebuild. Not neccesary, we already built in "build()"
• Added wiremix.toml.example to the package

edit:

• Removed pkgconf from makedepends, as it is already included in base-devel, https://wiki.archlinux.org/title/PKGBUILD#makedepends

# Maintainer: Adam Wahab <awahab@adhoc.tools>

_name=wiremix
pkgname=${_name,,}-git
pkgver=r430.c04c28a
pkgrel=1
pkgdesc="A simple TUI audio mixer for PipeWire"
url="https://github.com/tsowell/$_name"
arch=(x86_64)
license=(Apache-2.0 MIT)
depends=(libpipewire)
makedepends=(cargo clang libpipewire)
options=(!lto)
provides=($_name)
source=("git+${url}.git")
sha256sums=("SKIP")

pkgver() {
  cd "${srcdir}/$_name" || exit 1
  set -o pipefail
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  export RUSTUP_TOOLCHAIN=stable
  export CARGO_TARGET_DIR=target
  cd "${srcdir}/$_name" || exit 1
  cargo build --locked --release
}

package() {
  cd "${srcdir}/$_name" || exit 1
  install -Dm755 "target/release/$_name" "$pkgdir/usr/bin/$_name"
  install -Dm755 wiremix.toml "$pkgdir/usr/share/$_name/wiremix.toml.example"
  install -Dm644 LICENSE-APACHE LICENSE-MIT -t "${pkgdir}/usr/share/licenses/${pkgname}"
  install -Dm644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
}

[tsowell]

Sorry! I should have tested the package before mentioning it in the README. I've removed the instructions for now. Thanks for creating the issue with these changes - they look good to me.

Pinging the AUR maintainer: @ajwahab

[ajwahab]

@ManuLinares, thanks for the corrections!

@tsowell, the updated PKGBUILD is live. Thanks for sharing wiremix!

[ManuLinares]

Cheers!