[버그] Windows sandbox 실행되고 아무런 메시지 없이 Spork 설치 진행이 안됨

[jeongsu816]

버그에 대한 설명
윈도우11 사용중입니다. 식탁보로 sandbox 를 실행하면 sandbox 내에서 spork가 자동으로 실행이 되는 것으로 기대해는데요. sandbox 내부에 아무런 메시지 없이 그냥 sandbox 가 실행된 상태로 있습니다.
바탕화면에 App, Data, NPKI 디렉토리는 생성되어 있습니다.

재현 방법
구체적으로 해당 증상을 재현하는 방법을 단계별로 최대한 상세하게 알려주세요.

1. 식탁보에서 sandbox 실행

기대하는 동작
sandbox 실행하면 spork 동작이 이어짐

동영상 또는 스크린샷
https://drive.google.com/file/d/1bgwlpOE7IyOowv8hqgF7wSV9u7bMaaaV/view?usp=sharing

시스템 사양

• OS: Windows 11 25H2 (OS 빌드 26200.8875)
• CPU 아키텍처: 13th Gen Intel(R) Core(TM) i5-13600K
• 브라우저: Firefox 153.0
• 소프트웨어 릴리스 버전: 1.20.7

참고 사항
원래 windows 10 에서 사용할때는 잘 동작했습니다. windows 10 지원 종료로 windows 11로 업그레이드를 했는데 그 이후부터 spork 실행이 안되었어요. 그냥 참고 썼는데 버전이 올라가도 해결이 안되어서 이슈 등록합니다.

로그 획득 방법이라던지 개선 방법을 알려 주시면 적극적으로 대응하겠습니다.

[rkttu]

안녕하세요. 상세한 제보와 영상까지 첨부해주셔서 감사합니다. 적극적으로 대응해주시겠다고 하셔서, 원인을 좁힐 수 있는 진단 방법을 정리해 드립니다.

먼저, "아무 메시지도 없는" 이유

식탁보는 샌드박스가 부팅되면 바탕 화면의 App 폴더에 있는 StartupScript.cmd를 실행하고, 그 배치가 마지막에 TableCloth.exe spork를 띄우는 구조입니다. 그런데 지금 코드는 이 실행이 실패해도 결과를 확인하지 않고 배치가 그대로 끝나도록 되어 있습니다. 콘솔 창이 즉시 닫히기 때문에 오류 문구조차 화면에 남지 않습니다.

즉 "메시지가 하나도 없다"는 것은 특수한 증상이 아니라, Spork 프로세스가 뜨기도 전에 실패했다는 신호입니다. (로그가 안 남는 것도 같은 이유입니다. 이 부분은 제 쪽에서 개선하겠습니다.)

바탕 화면에 App / Data / NPKI 폴더가 보이는 것은 폴더 공유가 붙었다는 뜻일 뿐이라, 위 단계가 실행됐는지와는 무관합니다.

현재 가장 유력하게 보는 원인은 Windows 11의 Smart App Control(SAC)이 서명되지 않은 식탁보 실행 파일을 커널 단에서 차단하는 경우입니다. SAC는 Windows 11에만 있는 기능이라, "Windows 10에서는 잘 됐는데 업그레이드 후부터"라는 말씀과 시점이 정확히 맞습니다. (관련 선행 이슈: #256) 다만 이 경우 식탁보가 넣어둔 우회 코드가 동작해야 정상인데 그게 안 듣는 것인지, 아니면 배치 자체가 실행되지 않은 것인지에 따라 대응이 완전히 달라집니다. 그래서 이 둘을 가르는 확인이 필요합니다.

---

방법 A. 30초 확인 (이것만 해주셔도 큰 도움이 됩니다)

1. 평소처럼 식탁보로 샌드박스를 실행합니다.
2. Spork가 뜨지 않는 상태에서, 샌드박스 안에서 Win + R → cmd 입력 → 확인.
3. 열린 검은 창에 아래를 붙여넣고 Enter를 눌러주세요.

reg query "HKLM\SOFTWARE\Policies\Microsoft\Edge\LocalNetworkAccessAllowedForUrls" /v 1
reg query "HKLM\SYSTEM\CurrentControlSet\Control\CI\Policy" /v VerifiedAndReputablePolicyState
powershell -c "(Get-MpComputerStatus).SmartAppControlState"
cd /d "%USERPROFILE%\Desktop\App" && TableCloth.exe spork

4. 화면에 나온 결과를 캡처해서 올려주시면 됩니다.

특히 마지막 줄을 실행했을 때 무엇이 나오는지가 중요합니다. 액세스가 거부되었습니다, 이 앱은 차단되었습니다 같은 문구나 대화상자가 뜨면 그것까지 캡처 부탁드립니다.

---

방법 B. 전체 진단 (더 정확합니다)

증거를 한 번에 파일로 모으는 스크립트입니다. 결과 파일이 호스트(실제 PC) 쪽에도 그대로 보이므로 첨부하기 편합니다.

1. 실제 PC에서 문서 → TableCloth → Data 폴더를 엽니다. (식탁보 옵션에서 데이터 폴더를 따로 지정하셨다면 그 폴더입니다.)
2. 메모장을 열고 아래 내용을 그대로 붙여넣은 뒤, 그 폴더에 diagnose_sandbox_boot.cmd 라는 이름으로 저장합니다. (저장할 때 "파일 형식"을 모든 파일로 바꿔주세요. .txt가 붙으면 실행되지 않습니다.)

스크립트 내용 (펼치기)

@echo off
setlocal enabledelayedexpansion
set LOG=%~dp0tablecloth-diag.txt
set APPDIR=C:\Users\WDAGUtilityAccount\Desktop\App

echo ==== TableCloth sandbox boot diagnostics (issue #304) ====> "%LOG%"
echo [00] collected at %DATE% %TIME%>> "%LOG%"
whoami>> "%LOG%" 2>&1
ver>> "%LOG%" 2>&1

echo.>> "%LOG%"
echo [01] did the LogonCommand batch run?>> "%LOG%"
reg query "HKLM\SOFTWARE\Policies\Microsoft\Edge\LocalNetworkAccessAllowedForUrls" /v 1>> "%LOG%" 2>&1
reg query "HKLM\SOFTWARE\Policies\Microsoft\Edge" /v HardwareAccelerationModeEnabled>> "%LOG%" 2>&1

echo.>> "%LOG%"
echo [02] Smart App Control state (0=off 1=enforce 2=evaluation)>> "%LOG%"
reg query "HKLM\SYSTEM\CurrentControlSet\Control\CI\Policy" /v VerifiedAndReputablePolicyState>> "%LOG%" 2>&1
powershell -NoProfile -Command "try { 'SmartAppControlState = ' + (Get-MpComputerStatus).SmartAppControlState } catch { 'ERR: ' + $_.Exception.Message }">> "%LOG%" 2>&1
if exist "%SystemRoot%\System32\citool.exe" (echo citool.exe present>> "%LOG%") else (echo citool.exe MISSING>> "%LOG%")

echo.>> "%LOG%"
echo [03] App mount contents>> "%LOG%"
if exist "%APPDIR%\TableCloth.exe" (
  dir "%APPDIR%">> "%LOG%" 2>&1
) else (
  echo   %APPDIR%\TableCloth.exe NOT FOUND>> "%LOG%"
  dir "C:\Users\WDAGUtilityAccount\Desktop">> "%LOG%" 2>&1
)

echo.>> "%LOG%"
echo [04] launch TableCloth.exe spork and check survival>> "%LOG%"
if exist "%APPDIR%\TableCloth.exe" (
  echo Launching TableCloth.exe - if a "blocked" dialog pops up, screenshot it.
  start "" "%APPDIR%\TableCloth.exe" spork
  echo   start errorlevel=!errorlevel!>> "%LOG%"
  ping -n 21 127.0.0.1 >nul
  echo   --- tasklist after 20s --->> "%LOG%"
  tasklist /fi "imagename eq TableCloth.exe">> "%LOG%" 2>&1
) else (
  echo   SKIP - binary not present>> "%LOG%"
)

echo.>> "%LOG%"
echo [05] CodeIntegrity operational log (most recent 30 events)>> "%LOG%"
wevtutil qe Microsoft-Windows-CodeIntegrity/Operational /c:30 /rd:true /f:text>> "%LOG%" 2>&1

echo.>> "%LOG%"
echo [06] Windows PowerShell availability>> "%LOG%"
if exist "%SystemRoot%\System32\WindowsPowerShell\v1.0\powershell.exe" (
  echo   powershell.exe present>> "%LOG%"
  powershell -NoProfile -Command "$PSVersionTable.PSVersion.ToString()">> "%LOG%" 2>&1
  powershell -NoProfile -Command "(Get-ExecutionPolicy -List | Out-String)">> "%LOG%" 2>&1
) else (
  echo   powershell.exe MISSING>> "%LOG%"
)

echo.>> "%LOG%"
echo [07] DNS and catalog reachability>> "%LOG%"
ipconfig /all>> "%LOG%" 2>&1
nslookup yourtablecloth.app>> "%LOG%" 2>&1

echo.>> "%LOG%"
echo ==== done ====>> "%LOG%"

echo.
echo Diagnostics finished. Result: %LOG%
echo.
pause

3. 식탁보로 평소처럼 샌드박스를 실행합니다.
4. Spork가 뜨지 않으면, 샌드박스 안에서 Win + R → 아래를 붙여넣고 실행합니다.

%USERPROFILE%\Desktop\Data\diagnose_sandbox_boot.cmd

5. 20초 정도 뒤 Diagnostics finished 가 나오면 끝입니다. 실제 PC의 문서\TableCloth\Data\tablecloth-diag.txt 파일을 이 이슈에 첨부해주세요.

결과 파일에는 샌드박스 안의 네트워크 설정(ipconfig)도 포함됩니다. 샌드박스 내부 정보라 민감한 내용은 아니지만, 올리시기 전에 한 번 훑어보시고 불편한 부분이 있으면 지우고 올리셔도 됩니다.

---

추가로 알려주시면 좋은 것

실제 PC(샌드박스 밖)에서 PowerShell을 열고 아래를 실행한 결과입니다.

Get-AppxPackage -Name "*WindowsSandbox*" | Select-Object Name, Version
reg query "HKLM\SYSTEM\CurrentControlSet\Control\CI\Policy" /v VerifiedAndReputablePolicyState

25H2부터 Windows Sandbox가 스토어를 통해 배포되는 앱 형태로 바뀌어서, 버전에 따라 동작이 달라질 여지가 있어 확인하려는 것입니다.

---

번거로운 부탁을 드리게 되어 죄송합니다. 제 PC도 제보해주신 것과 동일한 빌드(25H2 26200.8875)라 재현을 시도해보고 있고, 결과를 주시면 그에 맞춰 대응하겠습니다.

원인과 무관하게, 이렇게 조용히 실패하면 아무 단서도 남지 않는 것 자체가 문제이므로 다음 버전에서는 부팅 단계 로그를 남기고 실행 실패 시 안내가 뜨도록 개선하겠습니다. 좋은 제보 감사합니다. 🙇

[jeongsu816]

방법 A 결과 먼저 공유 드려요

Microsoft Windows [Version 10.0.26100.8875]
(c) Microsoft Corporation. All rights reserved.

C:\Users\WDAGUtilityAccount>reg query "HKLM\SOFTWARE\Policies\Microsoft\Edge\LocalNetworkAccessAllowedForUrls" /v 1
오류: 오류: 시스템이 지정된 레지스트리 키 또는 값을 찾을 수 없습니다.

C:\Users\WDAGUtilityAccount>reg query "HKLM\SYSTEM\CurrentControlSet\Control\CI\Policy" /v VerifiedAndReputablePolicyState

HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\CI\Policy
VerifiedAndReputablePolicyState REG_DWORD 0x2

C:\Users\WDAGUtilityAccount>powershell -c "(Get-MpComputerStatus).SmartAppControlState"

C:\Users\WDAGUtilityAccount>cd /d "%USERPROFILE%\Desktop\App" && TableCloth.exe spork

C:\Users\WDAGUtilityAccount\Desktop\App>

마지막 명령 실행은 잘 되었습니다.

[jeongsu816]

방법 B 결과 첨부합니다. spork 실행은 잘 되었어요.

tablecloth-diag.txt

추가 확인 요청하신 부분이예요.

PS C:\Users\guava> Get-AppxPackage -Name "WindowsSandbox" | Select-Object Name, Version

Name Version

---

MicrosoftWindows.WindowsSandbox 0.8.107.0

PS C:\Users\guava> reg query "HKLM\SYSTEM\CurrentControlSet\Control\CI\Policy" /v VerifiedAndReputablePolicyState

HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\CI\Policy
VerifiedAndReputablePolicyState REG_DWORD 0x0

[jeongsu816]

추가로 sandbox 실행한 다음에 App 디렉토리에 StartupScript 를 그냥 실행하면 멈추어 있는데요. StartupScript에서 @echo off 와 >nul 2>&1 제거하고 실행해 보면 엔터 치라고 나오는 부분에서 멈추어 있어요.

C:\Users\WDAGUtilityAccount\Desktop\App>pushd "C:\Users\WDAGUtilityAccount\Desktop\App\"

C:\Users\WDAGUtilityAccount\Desktop\App>reg add "HKLM\SYSTEM\CurrentControlSet\Control\CI\Policy" /v VerifiedAndReputablePolicyState /t REG_DWORD /d 0 /f
작업을 완료했습니다.

C:\Users\WDAGUtilityAccount\Desktop\App>reg add "HKLM\SOFTWARE\Policies\Microsoft\Edge" /v HardwareAccelerationModeEnabled /t REG_DWORD /d 0 /f
작업을 완료했습니다.

C:\Users\WDAGUtilityAccount\Desktop\App>reg add "HKLM\SOFTWARE\Policies\Microsoft\Edge\LocalNetworkAccessAllowedForUrls" /v 1 /t REG_SZ /d "*" /f
작업을 완료했습니다.

C:\Users\WDAGUtilityAccount\Desktop\App>reg add "HKLM\SOFTWARE\Policies\Google\Chrome\LocalNetworkAccessAllowedForUrls" /v 1 /t REG_SZ /d "*" /f
작업을 완료했습니다.

C:\Users\WDAGUtilityAccount\Desktop\App>"C:\Windows\System32\citool.exe" --refresh
작업 성공
계속하려면 Enter 키를 누르세요.

그럼 sandbox 시작할 때 저 스크립트가 저기에서 멈추어 있는 건가? 해서 작업 관리자에서 보면 CiTool.exe 는 없어요. App 디렉토리의 StartupScript 를 직접 실행시키면 그때는 CiTool.exe 가 보이고요. 거기에서 엔터 치면 sport가 실행 되면서 CiTool.exe 도 사라집니다.

[rkttu]

보내주신 결과 덕분에 원인 후보가 많이 좁혀졌습니다. 특히 세 번째 댓글의 citool 관찰은 저 혼자서는 못 찾았을 내용입니다. 감사합니다.

먼저 정정드릴 것이 있습니다. 제가 처음에 가장 유력하게 봤던 Smart App Control은 원인이 아니었습니다. 보내주신 자료를 보면 VerifiedAndReputablePolicyState 값이 0x2, 즉 "평가" 모드라서 프로그램을 차단하지 않는 상태였습니다. 실제로 TableCloth.exe spork를 직접 실행하셨을 때 정상적으로 떴고, 진단 로그의 CodeIntegrity 이벤트에도 차단 기록이 전혀 없었습니다. 이슈 #256과는 다른 문제입니다. 엉뚱한 방향으로 안내드렸던 점 죄송합니다.

대신 찾아주신 citool 쪽이 훨씬 유력합니다. citool.exe --refresh가 "계속하려면 Enter 키를 누르세요."에서 멈춘다는 게 왜 치명적이냐면, StartupScript.cmd에서 멈출 수 있는 줄이 저 한 줄뿐이고 바로 다음 줄이 Spork를 실행하는 줄이기 때문입니다. 게다가 원래 스크립트는 저 줄의 출력을 감춰두기 때문에 프롬프트조차 화면에 나타나지 않습니다. 표준 입력을 비워서 프롬프트가 떠도 그냥 지나가도록 수정했습니다.

다만 솔직하게 말씀드리면, 제 PC에서는 이 대기 현상이 재현되지 않았습니다. 같은 Windows Sandbox 앱 버전(0.8.107.0)으로 여러 번 돌려봤지만 citool이 0.5초 안에 끝나고 Spork까지 정상 실행됐습니다. 그래서 이 수정으로 해결될 수도 있지만 확신할 수는 없는 상태입니다.

그래서 이번에 드리는 테스트 빌드에는 수정과 함께 부팅 과정을 파일로 기록하는 기능을 넣었습니다. 지금까지는 Spork가 뜨기 전에 실패하면 아무 흔적도 남지 않았는데, 이제는 이런 식으로 남습니다.

[00] startup script begin ...
[01] sac policy rc=0
[02] browser policies applied rc=0
[03] citool refresh begin ...
[04] citool refresh end rc=0 ...
[05] launching spork ...
[06] spork exited rc=...

이 기록이 어디서 끊겼는지가 곧 실패 지점이라, 한 번만 실행해 주시면 원인이 확정됩니다.

빌드는 아래 링크에서 받으실 수 있습니다. GitHub에 로그인된 상태여야 내려받아지고, CI 산출물이라 5일 뒤 자동으로 삭제됩니다.

TableCloth-Portable-x64 내려받기 (약 101MB)

1. 링크에서 TableCloth-Portable-x64 를 내려받아 압축을 풉니다.
2. 그 안의 TableCloth_1.20.8.0_Release_x64_Portable.zip 을 다시 풀어주세요. 지금 쓰시는 식탁보 설치본은 건드리지 않고 폴더에서 바로 실행되는 형태입니다.
3. 풀린 폴더의 TableCloth.exe 를 실행합니다. 코드 서명이 없는 빌드라 "Windows의 PC 보호" 경고가 뜨는데, 추가 정보 → 실행을 눌러주세요.
4. 평소처럼 샌드박스를 실행합니다.

샌드박스를 실행하신 뒤에는 Spork가 뜨든 안 뜨든, 실제 PC의 문서\TableCloth\Data\tablecloth-boot.log 파일을 이 이슈에 첨부해 주시면 됩니다. 식탁보 옵션에서 데이터 폴더를 따로 지정하셨다면 그 폴더 안에 있습니다.

그리고 Spork가 정상적으로 떴다면 그 사실도 꼭 알려주세요. 그러면 위 citool 수정만으로 해결된 것이 되므로 그대로 정식 릴리스에 반영하겠습니다.

번거로운 부탁을 계속 드리게 되어 죄송합니다. 보내주시는 자료마다 조사가 한 단계씩 진전되고 있어서 정말 큰 도움이 되고 있습니다. 🙇

_{관련 PR: #305}

[jeongsu816]

첨부해주신 버전으로 테스트 결과 알려드려요.

결론적으로는 spork 가 자동으로 실행되지 않아요. StartupScript.cmd 자체가 실행이 안되는 모양이예요. 이전 코멘트에서 CiTool.exe 이야기도 그 의미였어요. 실행되어서 멈추어 있었다면 작업관리자에서 CiTool.exe 가 보였을 테니까요.

그래도 App 디렉토리에서 StartupScript.cmd 를 직접 실행시키면 이번에는 마지막 spork 까지 실행이 잘 됩니다. 이 과정에서 생성된 로그 파일 업로드 합니다.
tablecloth-boot.log

[rkttu]

상세하게 정보를 공유해주셔서 정말 감사드립니다. 🙏

LogonCommand가 .cmd 파일을 실행하지 못할 수 있는 원인으로 한 가지 더 가설을 세워보려 하는데, Shell Execution을 타지 않도록 바꾸면 더 명확할 것으로 생각하여 아래처럼 바꾼 빌드를 제작했습니다.

- <Command>C:\Users\WDAGUtilityAccount\Desktop\App\StartupScript.cmd</Command>
+ <Command>C:\Windows\System32\cmd.exe /c "C:\Users\WDAGUtilityAccount\Desktop\App\StartupScript.cmd"</Command>

다만 제 PC에서는 이렇게 바꾸지 않았어도 정상 동작했던 터라 이 수정이 해결책이라고 확신하지는 못합니다. 그래서 아래 두 가지를 함께 부탁드립니다.

TableCloth-Portable-x64 내려받기 (약 101MB)

압축을 풀고 그 안의 TableCloth_1.20.8.0_Release_x64_Portable.zip을 다시 푼 뒤 TableCloth.exe를 실행하시면 됩니다.

하나. 샌드박스를 띄운 직후, StartupScript.cmd를 수동 실행하기 전에 문서\TableCloth\Data\tablecloth-boot.log 파일이 있는지 확인해 주세요. 이 파일은 실행할 때마다 덮어쓰기 때문에, 지난번 로그가 자동 실행분인지 수동 실행분인지 구분이 되지 않았습니다. 파일이 없으면 없다는 사실만 알려주셔도 충분합니다.

둘. 식탁보를 켜 둔 상태에서 아래 파일을 복사해 첨부해 주시면 감사하겠습니다.

%LocalAppData%\TableCloth.Data\Sandbox\InternetBankingSandbox.wsb

식탁보가 샌드박스에 넘기는 설정 파일 원본입니다. 지금까지 제가 재현에 쓴 파일들은 추측으로 흉내 낸 것이라, 실물을 보면 제 환경과 무엇이 다른지 바로 확인할 수 있습니다. 식탁보 창을 닫으면 삭제되니 샌드박스가 떠 있는 동안 복사해 주셔야 합니다.

고맙습니다! 🙇

[jeongsu816]

일단 기존에 있던 tablecloth-boot.log 파일을 삭제하고 진행했습니다.

1. 해당 파일 생성되지 않습니다.
2. 수동으로 실행 중에 봤는데 해당 디렉토리가 없습니다.

C:\Users\WDAGUtilityAccount>echo %LocalAppData%
C:\Users\WDAGUtilityAccount\AppData\Local

C:\Users\WDAGUtilityAccount>cd %LocalAppData%

C:\Users\WDAGUtilityAccount\AppData\Local>dir /a
 C 드라이브의 볼륨에는 이름이 없습니다.
 볼륨 일련 번호: CCC7-6EA3

 C:\Users\WDAGUtilityAccount\AppData\Local 디렉터리

2026-07-27  오후 10:01    <DIR>          .
2026-07-26  오후 01:33    <DIR>          ..
2026-07-26  오후 01:33    <JUNCTION>     Application Data [C:\Users\WDAGUtilityAccount\AppData\Local]
2026-07-26  오후 01:33    <DIR>          ConnectedDevicesPlatform
2026-07-27  오후 09:59    <DIR>          D3DSCache
2026-07-26  오후 01:33    <JUNCTION>     History [C:\Users\WDAGUtilityAccount\AppData\Local\Microsoft\Windows\History]
2026-07-26  오후 01:33             8,280 IconCache.db
2026-07-27  오후 09:59    <DIR>          Microsoft
2026-07-26  오후 01:33    <DIR>          Packages
2026-07-27  오후 10:01    <DIR>          Sentry
2026-07-26  오후 01:33    <DIR>          Temp
2026-07-26  오후 01:33    <JUNCTION>     Temporary Internet Files [C:\Users\WDAGUtilityAccount\AppData\Local\Microsoft\Windows\INetCache]
               1개 파일               8,280 바이트
              11개 디렉터리  83,040,555,008 바이트 남음

C:\Users\WDAGUtilityAccount\AppData\Local>