ERC20

pragma solidity ^0.5.0;

import "./SafeMath.sol";


contract ERC20 {
    
    // event
    event Transfer(address indexed from, address indexed to, uint256 value);
    event Approval(address indexed owner, address indexed spender, uint256 value);
    
    // uint256 using security functions
    using SafeMath for uint256;

    // Address balance mapping
    mapping (address => uint256)  _balances;
    // Amount mapping of address authorization to transfer address
    mapping (address => mapping (address => uint256))  _allowances;

    // Return address balance
    function balanceOf(address account) public view returns (uint256) {
        return _balances[account];
    }


    // Current address (msg.ender) to designated address (recipient) transfer (amount)
    function transfer(address recipient, uint256 amount) public returns (bool) {
        _transfer(msg.sender, recipient, amount);
        return true;
    }

    // Return the current transfer amount authorized by the address (owner) to the address (spender)
    function allowance(address owner, address spender) public view returns (uint256) {
        return _allowances[owner][spender];
    }

    // Current address (msg.sender) authorizes address (spender) to transfer amount (amount)
    function approve(address spender, uint256 amount) public returns (bool) {
        _approve(msg.sender, spender, amount);
        return true;
    }

    
    //Address (sender) authorized by current address (msg.sender) operation to transfer (amount) 
    //to address (recipient)
    function transferFrom(address sender, address recipient, uint256 amount) public returns (bool) {
        _approve(sender, msg.sender, _allowances[sender][msg.sender].sub(amount, "ERC20: transfer amount exceeds allowance"));
        _transfer(sender, recipient, amount);
        
        return true;
    }

    function _transfer(address sender, address recipient, uint256 amount) internal {
        require(sender != address(0), "ERC20: transfer from the zero address");
        require(recipient != address(0), "ERC20: transfer to the zero address");

        _balances[sender] = _balances[sender].sub(amount, "ERC20: transfer amount exceeds balance");
        _balances[recipient] = _balances[recipient].add(amount);
        emit Transfer(sender, recipient, amount);
    }


    function _approve(address owner, address spender, uint256 amount) internal {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }
    
}