CraftTweaker [Campfire Cooking Recipes]

CraftTweaker [Campfire Cooking Recipes]

Campfire cooking recipes are added with the command:
mods.campfirebackport.addCampfireRecipe(String types, IIngredient input OR IIngredient[] input, IItemStack output, @Optional Integer cookingTime, @Optional String signalFire, @Optional IItemStack byproduct, @Optional Double byproductChance);

• String types
  The campfire types this recipe applies to. Must be "regular", "soul", or "both".
• IIngredient input OR IIngredient[] input
  Up to 4 inputs in an array, because a campfire has 4 slots.
  If it's just 1 input, you don't have to put it in an array.
• IItemStack output
  The output.
• @Optional Integer cookingTime
  It's the number of ticks until the item cooks.
  For inputs that are more than one item, all items must have reached this cooking time.
  If not included, or set to null, the recipe will use the default cooking time.
  The default cooking time is 600 ticks (30 seconds), but it can be changed in the config.
  
• @Optional String signalFire
  If "signal", the campfire must be a signal fire to cook this recipe.
  If "notsignal", the campfire must NOT be a signal fire to cook this recipe.
  If "any", it doesn't matter.
  If not included, it defaults to "any".
• @Optional IItemStack byproduct
  It's simply another output that can have a chance to be produced.
• @Optional Double byproductChance
  This is the chance for the byproduct to be produced.
  It's a decimal number between 0.0 and 1.0.
  If not included, it defaults to 1.0 (100%).

Some example recipes:

• A glass bottle turns into a water bottle after 63 ticks on any campfire
  mods.campfirebackport.addCampfireRecipe("both", <minecraft:glass_bottle>, <minecraft:potion>, 63);
• An iron ingot and a gold ingot turn into an emerald on regular campfires
  mods.campfirebackport.addCampfireRecipe("regular", [<ore:ingotIron>, <ore:ingotGold>], <minecraft:emerald>);
• A diamond axe turns into two full stacks of redstone after 2 ticks on a soul campfire that isn't a signal fire
  mods.campfirebackport.addCampfireRecipe("soul", <minecraft:diamond_axe:*>, <minecraft:redstone> * 64, 2, "notsignal", <minecraft:redstone> * 64);
• 1 brown mushroom, 1 red mushroom, and 1 bowl turns into mushroom stew, but only on signal fire campfires
  mods.campfirebackport.addCampfireRecipe("both", [<minecraft:brown_mushroom>, <minecraft:red_mushroom>, <minecraft:bowl>], <minecraft:mushroom_stew>, null, "signal");
• 4 of any planks turn into 3 diamonds after 4821 ticks on a soul campfire that is a signal fire
  mods.campfirebackport.addCampfireRecipe("soul", [<ore:plankWood>, <ore:plankWood>, <ore:plankWood>, <ore:plankWood>], <minecraft:diamond> * 3, 4821, "signal");
• Make an iron ingot with the lore "wibbly wobbly" and have a 50% chance of a gold ingot after 221 ticks by putting a sand (or a red sand) and a dirt (or a podzol) on any campfire
  mods.campfirebackport.addCampfireRecipe("both", [<minecraft:sand:*>, <minecraft:dirt:*>], <minecraft:iron_ingot>.withTag({display: {Lore:["wibbly wobbly"]}}), 221, "any", <minecraft:gold_ingot>, 0.5);

---

Tips:

• Pressing the "uses" hotkey when hovering over a campfire in NEI will bring up all Recipes and Extinguishers / Ignitors.
• Cooking times in NEI are rounded to an easily readable number of seconds or minutes. Holding Shift will display times in exact ticks.
• When using a damageable item as an input, don't forget to set its damage as a wildcard. For example, <minecraft:iron_sword> only applies to undamaged iron swords, but <minecraft:iron_sword:*> applies to iron swords with any amount of damage.
• Wildcard inputs will display in NEI as a written book.
• If you want to use NBT tags in your recipe inputs, check out [Working with NBT Tags in CraftTweaker].
• If you want to use fluids in your recipe inputs, check out [Working with Fluid Containers in CraftTweaker].