CraftTweaker [Campfire Extinguishers & Ignitors]

CraftTweaker [Campfire Extinguishers / Ignitors]

Campfire Extinguishers / Ignitors are added with the commands:
mods.campfirebackport.addCampfireExtinguisher(String types, IIngredient input, String usageType, @Optional int damageOrReduceBy, @Optional IItemStack output, @Optional boolean leftClick);
mods.campfirebackport.addCampfireIgnitor(String types, IIngredient input, String usageType, @Optional int damageOrReduceBy, @Optional IItemStack output, @Optional boolean leftClick);

• String types
  The campfire types this extinguisher / ignitor applies to. Must be "regular", "soul", or "both".
• IIngredient input
  The input used to extinguish / ignite the campfire.
• String usageType
  How the input is used up. Must be "damageable", "stackable", or "none".
  If "damageable", attempts to damage the input. Use this one if the input has durability.
  If "stackable", the input will be reduced in stack size.
  If "none", neither will happen.
• @Optional int damageOrReduceBy
  How much the input is damaged / reduced by.
  If usageType is "damageable", the input will be damaged by this amount.
  If usageType is "stackable", the input is required to have at least this stack size to be used, and will be reduced in stack size by this amount.
  If usageType is "none", the input won't be damaged or reduced in stack size. The input is still required to have this stack size to be used, however.
  If not included, defaults to 1.
• @Optional IItemStack output
  A byproduct that is given to the player after extinguishing / igniting.
  If not included, defaults to null.
• @Optional boolean leftClick
  If true, the extinguisher / ignitor is used by left clicking the campfire.
  If false, the extinguisher / ignitor is used by right clicking the campfire.
  If not included, defaults to false.
  Since right clicking a campfire checks for cooking recipes first, you might want to set this to true if the input is also a cooking recipe input.

Some example extinguishers/ignitors:

• Right-clicking with a milk bucket extinguishes campfires and gives the player back an empty bucket
  mods.campfirebackport.addCampfireExtinguisher("both", <minecraft:milk_bucket>, "stackable");
• Right-clicking with an iron hoe extinguishes soul campfires and damages the item by 6 points
  mods.campfirebackport.addCampfireExtinguisher("soul", <minecraft:iron_hoe:*>, "damageable", 6);
• Right-clicking with 3 of any glass block ignites campfires and gives the player 2 sand blocks named "Martha"
  mods.campfirebackport.addCampfireIgnitor("both", <ore:blockGlass>, "stackable", 3, (<minecraft:sand> * 2).withTag({display: {Name:"Martha"}}));
• Left-clicking with a boat extinguishes regular campfires and gives the player 3 oak planks
  mods.campfirebackport.addCampfireExtinguisher("regular", <minecraft:boat>, "stackable", 1, <minecraft:planks> * 3, true);
• Left-clicking with a flint and steel extinguishes soul campfires
  mods.campfirebackport.addCampfireExtinguisher("soul", <minecraft:flint_and_steel:*>, "damageable", 1, null, true);

---

Tips:

• Pressing the "uses" hotkey when hovering over a campfire in NEI will bring up all Recipes and Extinguishers / Ignitors.
• When using a damageable item as an input, don't forget to set its damage as a wildcard. For example, <minecraft:iron_sword> only applies to undamaged iron swords, but <minecraft:iron_sword:*> applies to iron swords with any amount of damage.
• Wildcard inputs will display in NEI as a written book.
• If you want to use NBT tags in your recipe inputs, check out [Working with NBT Tags in CraftTweaker].
• If you want to use fluids in your recipe inputs, check out [Working with Fluid Containers in CraftTweaker].