How do I use the result of a plan function in my Starlark?

[mieubrisse]

I'm doing a plan function call, and I want to use the return value in my code. For example:

recipe = ExecRecipe(command=["/bin/sh", "-c", "curl -XGET %s" % my_service.url])
result = plan.exec(service_name=service_name, recipe=recipe)

stripped_result = result["output"].strip()
if stripped_result == "":
    plan.print("Result is empty")

How can I do this?

[mieubrisse]

This isn't possible in current Kurtosis. Kurtosis uses a multi-phase approach when running, which means that all Starlark will be completely interpreted and done before any execution happens.

This has the benefit that Kurtosis can validate the complete plan of what the user is trying to do before anything runs, but has the downside that execution-time values (such as the result of curl) are not available in Starlark because the curl hasn't run yet.

Instead, the same thing can be accomplished by pushing the dynamic logic down to execution-time computation. For example:

recipe = ExecRecipe(command=["/bin/sh", "-c", "curl -XGET %s" % my_service.url])
result = plan.exec(service_name=service_name, recipe=recipe)

evalute_is_empty_result = plan.run_sh("""
stripped_result="$(echo "%s" | xargs)"
if [ "${stripped_result}" = "" ]; then
    echo "Result is empty"
fi
""" % result["output"])

plan.print(evalute_is_empty_result["output"])

Note that this is not exactly the same as the original code, because the plan.print(evalute_is_empty_result["output"]) will get printed regardless. This happens because, in order for Kurtosis to validate the plan, it must not be dynamic based on runtime values.

To see why, consider the following code that gets the image of the service from an execution-time value:

# Gets which Docker image we want to use, dynamically at execution time
latest_alpine_image = plan.run_sh("echo 'alpne:latest'")

plan.add_service(
    name = "my-alpine-service",
    config = ServiceConfig(
        image = latest_alpine_image["output"],
        cmd = ["echo", "Hello, world!"],
    )
)

At Starlark interpretation time (the time that plan.add_service is executed), the echo 'alpne:latest' won't have been run yet. This means that Kurtosis won't know which image my-alpine-service should be started with, meaning Kurtosis can't validate if the image even exists.

In this case, there's a typo - alpne:latest should be alpine:latest - but this failure would only be caught at execution time. Kurtosis' philosophy is to alert the author to errors as quickly as possible, which is why we use the multi-phase run approach.