Improve 'slice of single-item pointer' error message

src/Sema.zig

@@ -29297,7 +29297,44 @@ fn analyzeSlice(
                     array_ty = double_child_ty;
                     elem_ty = double_child_ty.childType();
                 } else {
-                    return sema.fail(block, src, "slice of single-item pointer", .{});
+                    const emit_note = emit_note: {
+                        const start_val = try sema.resolveDefinedValue(block, start_src, uncasted_start) orelse {
+                            break :emit_note false;
+                        };
+                        const start = try start_val.getUnsignedIntAdvanced(sema.mod.getTarget(), sema) orelse {
+                            break :emit_note false;
+                        };
+                        const end = end: {
+                            if (uncasted_end_opt == .none) {
+                                break :end 1;
+                            } else {
+                                const end_val = try sema.resolveDefinedValue(block, end_src, uncasted_end_opt) orelse {
+                                    break :emit_note false;
+                                };
+                                break :end try end_val.getUnsignedIntAdvanced(sema.mod.getTarget(), sema) orelse {
+                                    break :emit_note false;
+                                };
+                            }
+                        };
+                        break :emit_note (start == 0) and (end == 1);
+                    };
+                    if (emit_note) {
+                        const msg = msg: {
+                            const msg = try sema.errMsg(block, src, "slice of single-item pointer", .{});
+                            errdefer msg.destroy(sema.gpa);
+                            try sema.errNote(
+                                block,
+                                src,
+                                msg,
+                                "single-item pointer can be coerced to array using '@as(*[1]{}, ptr)'",
+                                .{ptr_ptr_child_ty.childType().fmt(mod)},
+                            );
+                            break :msg msg;
+                        };
+                        return sema.failWithOwnedErrorMsg(msg);
+                    } else {
+                        return sema.fail(block, src, "slice of single-item pointer", .{});
+                    }
                 }
             },
             .Many, .C => {

test/cases/compile_errors/slicing_single-item_pointer_with_len_1.zig

@@ -0,0 +1,11 @@
+export fn entry(ptr: *i32) void {
+    const slice = ptr[0..];
+    _ = slice;
+}
+
+// error
+// backend=stage2
+// target=native
+//
+// :2:22: error: slice of single-item pointer
+// :2:22: note: single-item pointer can be coerced to array using '@as(*[1]i32, ptr)'